[ABAP] Arbeit mit cl_dd_document (Dynamische Dokumente)

* Paket:
SDYNAMICDOCUMENTS

* Demoprogramme für cl_dd_document:

DD_ACC_TEST_FORM_ELEMENTS
DD_ACC_TEST_TABLE
DD_ADD_FORM_BUTTON
DD_ADD_FORM_INPUT
DD_ADD_LINK
DD_ADD_LINK_SCROLLED
DD_ADD_PICTURE
DD_ADD_TABLE
DD_ADD_TEXT
DD_ALV_FREE_TOP
DD_ALV_STANDARD_TOP
DD_SIMPLE_ALV_TOP
DD_SPLIT_DOCUMENT
DD_STYLE_TABLE

* DD-Konstanten:
* background_color

* cl_dd_area=>col_textarea
* cl_dd_area=>col_background_level1
* cl_dd_area=>col_background_level2
* cl_dd_area=>col_tree_level1
* cl_dd_area=>col_tree_level2
* cl_dd_area=>col_tree_level3
* cl_dd_area=>col_tree_level4

* sap_style

* cl_dd_area=>heading       " schwarz
* cl_dd_area=>table_heading " blau
* cl_dd_area=>key           " hellblau
* cl_dd_area=>success       " grün
* cl_dd_area=>warning       " rot

* sap_fontstyle

* cl_dd_area=>standard
* cl_dd_area=>sans_serif  " Arial
* cl_dd_area=>serif       " Times

* sap_fontsize

* cl_dd_area=>small
* cl_dd_area=>medium
* cl_dd_area=>large
* cl_dd_area=>extra_large

* sap_emphasis

* cl_dd_area=>strong    " bold
* cl_dd_area=>emphasis  " italic

* sap_color

* cl_dd_area=>list_normal
* cl_dd_area=>list_normal_int
* cl_dd_area=>list_normal_inv
* cl_dd_area=>list_key
* cl_dd_area=>list_key_int
* cl_dd_area=>list_key_inv
* cl_dd_area=>list_background
* cl_dd_area=>list_background_int
* cl_dd_area=>list_background_inv
* cl_dd_area=>list_heading
* cl_dd_area=>list_heading_int
* cl_dd_area=>list_heading_inv
* cl_dd_area=>list_total
* cl_dd_area=>list_total_int
* cl_dd_area=>list_total_inv
* cl_dd_area=>list_positive
* cl_dd_area=>list_positive_int
* cl_dd_area=>list_positive_inv
* cl_dd_area=>list_negative
* cl_dd_area=>list_negative_int
* cl_dd_area=>list_negative_inv
* cl_dd_area=>list_group
* cl_dd_area=>list_group_int
* cl_dd_area=>list_group_inv

Links

[ABAP] Verwendung von Tabellen in cl_dd_document (Dynamische Dokumente)

TRY.
* DD-Dokumentobjekt anlegen und Hintergrundfarbe festlegen
    DATA(o_doc) = NEW cl_dd_document( background_color = cl_dd_area=>col_textarea ).

* max. 255 Zeichen
    o_doc->add_text( text          = 'Fluginformationen'
                     sap_style     = cl_dd_document=>heading ).

* Trennlinie
    o_doc->underline( ).

* Text
    o_doc->add_text( text          = 'Tabelle:'
                     sap_emphasis  = cl_dd_document=>strong
                     sap_fontstyle = cl_dd_area=>serif ).

* Leerzeile
    o_doc->new_line( ).

    DATA: o_table TYPE REF TO cl_dd_table_element.
    DATA: o_table_area TYPE REF TO cl_dd_table_area.

* Tabelle mit 2 Spalten anlegen
    o_doc->add_table( EXPORTING
                        no_of_columns               = 2
                        cell_background_transparent = abap_false
                      IMPORTING
                        table                       = o_table
                        tablearea                   = o_table_area ).

* Spalte 1, Stil hellblau
    o_table->set_column_style( col_no    = 1
                               sap_style = cl_dd_area=>key ).

* Tabelle hat 2 Spalten, daher 2 Texte hinzufügen
    o_table_area->add_text( text = 'Fluggesellschaft' sap_emphasis = cl_dd_area=>strong ).
    o_table_area->add_text( text = 'LH' ).

* Zeile voll - weiter zur nächsten Zeile
    o_table_area->new_row( ).

    o_table_area->add_text( text = 'Flugnummer' sap_emphasis = cl_dd_area=>strong ).
    o_table_area->add_text( text = '400' ).

* Zweite Zeile voll
    o_table_area->new_row( ).

* Zeile 3
    o_table_area->add_text( text = 'Von' sap_emphasis = cl_dd_area=>strong ).
    o_table_area->add_text( text = 'Frankfurt' ).

* Dritte Zeile voll
    o_table_area->new_row( ).

* Zeile 4
    o_table_area->add_text( text = 'Nach' sap_emphasis = cl_dd_area=>strong ).
    o_table_area->add_text( text = 'New York' ).

* Vierte Zeile voll
    o_table_area->new_row( ).

* Dokumentelemente zusammenführen
    o_doc->merge_document( ).
* Dokument im Standardcontainer anzeigen
    o_doc->display_document( parent = cl_gui_container=>default_screen ).

* erzwingen von cl_gui_container=>default_screen
    WRITE space.

  CATCH cx_root INTO DATA(e_txt).
    WRITE: / e_txt->get_text( ).
ENDTRY.

[ABAP] Textausgabe mit cl_dd_document (Dynamische Dokumente) in einem cl_gui_docking_container

DATA: it_spfli TYPE STANDARD TABLE OF spfli.

DATA: o_cnt TYPE REF TO cl_gui_docking_container.
DATA: o_doc TYPE REF TO cl_dd_document.

PARAMETERS: p_carr TYPE spfli-carrid DEFAULT '%'.

INITIALIZATION.
* Containerobjekt für die Einbettung des cl_dd_document
  o_cnt = NEW #( no_autodef_progid_dynnr = abap_true
                 side  = cl_gui_docking_container=>dock_at_bottom
                 ratio = 85 ).

* cl_dd_document für die formatierte Darstellung des Ausgabetextes
  o_doc = NEW #( background_color = cl_dd_area=>col_textarea ).
* Dokument im Container darstellen
  o_doc->display_document( parent = o_cnt ).

AT SELECTION-SCREEN OUTPUT.

  IF o_cnt IS BOUND.
* SELECT mit LIKE, für % als Wildcard
    SELECT * FROM spfli
      INTO TABLE @it_spfli
      WHERE carrid LIKE @p_carr.

* Dokument initialisieren, alten Inhalt löschen, Hintergrundfarbe weiß
    o_doc->initialize_document( background_color = cl_dd_area=>col_textarea ).
* Text vom Stil Überschrift
    o_doc->add_text( text      = 'Flugverbindungen'
                     sap_style = cl_dd_document=>heading ).

* Trennlinie
    o_doc->underline( ).

    LOOP AT it_spfli ASSIGNING FIELD-SYMBOL(<fs_line>).
* Zeilen im Standardformat
      o_doc->add_text( text      = |{ <fs_line>-carrid } { <fs_line>-connid } { <fs_line>-airpfrom } { <fs_line>-cityfrom } { <fs_line>-airpto } { <fs_line>-cityto }|
                       sap_style = cl_dd_document=>standard ).

      o_doc->new_line( ).
    ENDLOOP.

* Dokument zusammenbauen
    o_doc->merge_document( ).
* Dokument anzeigen, bisherige Controls, Ereignisbehandler und Container beibehalten
    o_doc->display_document( reuse_control = abap_true
                             reuse_registration = abap_true
                             parent = o_cnt ).
  ENDIF.