[ABAP] SAP Gateway File-Download über DEFINE und GET_STREAM

SE80: DDIC-Typ anlegen „ZFILESTREAM“

Feldname    Name im Gateway   ABAP-Typ     Bemerkung
------------------------------------------------------------------------------------------------------------------
FILEKEY     FileKey           beliebig     eindeutige Referenz (Key) zur späteren Ermittelung der Datei im Backend
MIME_TYPE   MimeType          CHAR100      Platzhalter für MimeType der Datei
VALUE       Value             XSTRINGVAL   Platzhalter für Binärdaten

SEGW: neuer Entitätstyp zum Lesen der Datei

  • Name: „FileStream“, DDIC-Typ „ZFILESTREAM“ importieren
Name      Schlüssel   EDM-Coretyp   Bezeichner        ABAP-Feldname
-------------------------------------------------------------------
FileKey   ja          Edm.String    FileId            FILEKEY
MimeType  nein        Edm.String    Mimetyp           MIME_TYPE
Value     nein        Edm.Binary    Media Ressource   VALUE
  • Haken bei Medium setzen

SE80: ZCL_…_MPC_EXT~DEFINE redefinieren

METHOD define.
  DATA: lo_entity   TYPE REF TO /iwbep/if_mgw_odata_entity_typ.
  DATA: lo_property TYPE REF TO /iwbep/if_mgw_odata_property.

* Aufruf Basisklasse
  super->define( ).

* Entität "FileStream" holen
  lo_entity = model->get_entity_type( iv_entity_name = zcl_..._mpc=>gc_filestream ).

  IF lo_entity IS BOUND.

* Feld für MimeType (==MIME_TYPE) als ContentType setzen
    lo_property = lo_entity->get_property( iv_property_name = 'MimeType' ).
    lo_property->set_as_content_type( ).

  ENDIF.
ENDMETHOD.

SE80: /IWBEP/IF_MGW_APPL_SRV_RUNTIME~GET_STREAM redefinieren

METHOD /iwbep/if_mgw_appl_srv_runtime~get_stream.
  DATA: lv_file        TYPE zcl_..._mpc=>ts_filestream.
  DATA: lv_stream      TYPE ty_s_media_resource.

* Welche Entität?
  CASE io_tech_request_context->get_entity_type_name( ).
    WHEN zcl_..._mpc=>gc_filestream.
* Schlüssel ("FILEKEY") ermitteln
      io_tech_request_context->get_converted_keys( IMPORTING es_key_values = lv_file ).

* gewünschte Binärdaten anhand des Schlüssels aus SAP lesen
      DATA: it_bin_data TYPE STANDARD TABLE OF raw255.
      
      it_bin_data = ...

* Dateinamen ermitteln        
      DATA: lv_filename TYPE skwf_filnm.
      
      lv_filename = ...

* Für die Umwandlung die Dateigröße der Binärdaten berechnen
      DATA(lv_size) = lines( it_bin_data ).
      DATA: lv_line LIKE LINE OF it_bin_data.
      DATA(lv_length) = 0.
* für Unicode-Kompatibilität IN BYTE MODE
      DESCRIBE FIELD lv_line LENGTH lv_length IN BYTE MODE.
      lv_size = lv_size * lv_length.

* Binärdaten in xstring für die Rückgabe konvertieren        
      CALL FUNCTION 'SCMS_BINARY_TO_XSTRING'
        EXPORTING
          input_length = lv_size
        IMPORTING
          buffer       = lv_stream-value
        TABLES
          binary_tab   = it_bin_data
        EXCEPTIONS
          failed       = 1
          OTHERS       = 2.

      IF sy-subrc = 0.        
* MIME-Typen der Datei ermitteln und an das Frontend übergeben
        DATA: lv_mimetype TYPE skwf_mime.
              
* aus Dateinamen den MIME-Typen ermitteln
        CALL FUNCTION 'SKWF_MIMETYPE_OF_FILE_GET'
          EXPORTING
            filename = lv_filename
          IMPORTING
            mimetype = lv_mimetype.
                
        lv_stream-mime_type = lv_mimetype.

* HTTP-Header-Infos setzen (Dateiname usw.)
        DATA(lv_lheader) = VALUE ihttpnvp( name  = 'Content-Disposition'
                                           value = |inline; filename="{ escape( val = lv_filename format = cl_abap_format=>e_url ) }";| ). " Datei im Tab inline (Plugin) öffnen
*                                           value = |outline; filename="{ escape( val = lv_filename format = cl_abap_format=>e_url ) }";| ). " Datei zum direkten Herunterladen / Öffnen anbieten

        set_header( is_header = lv_lheader ).

* alle Daten zum Frontend schicken
        me->copy_data_to_ref( EXPORTING is_data = lv_stream
                              CHANGING cr_data  = er_stream ).
      ENDIF.

    WHEN OTHERS.
* andere Entitäten standardmäßig behandeln
      super->/iwbep/if_mgw_appl_srv_runtime~get_stream(
        EXPORTING
          iv_entity_name          = iv_entity_name
          iv_entity_set_name      = iv_entity_set_name
          iv_source_name          = iv_source_name
          it_key_tab              = it_key_tab
          it_navigation_path      = it_navigation_path
          io_tech_request_context = io_tech_request_context
          IMPORTING
            er_stream             = er_stream
            es_response_context   = es_response_context ).
  ENDCASE.
ENDMETHOD.

Weiterführende Infos: SAP Fiori tricks: Get rid of $value in PDF display/downloads

[OData] Übersicht zu SAP-Options

Option                 | Beschreibung                                             | Link
-----------------------+----------------------------------------------------------+--------------------------------------------------------------------------------------------------------------
?sap-language=DE       | Sprachstrings explizit für Sprache DE aus dem DDIC holen |
?sap-client=123        | Daten für Mandant 123 abfragen                           |
?sap-statistics=true   | Performance-Statistiken im Header mitliefern             | https://blogs.sap.com/2016/01/28/understanding-sap-performance-statistics-for-sap-netweaver-gateway-service/
?sap-ds-debug=true     | Debugmode mit eigenständiger HTML-Seite und Links        | https://blogs.sap.com/2013/07/18/nw-gateway-tips-tricks/
?sap-ds-debug=download | Debug-HTML als Download                                  | https://blogs.sap.com/2013/07/18/nw-gateway-tips-tricks/

[OData] System-Adminstration Frontend / Backend

Schritte

  • SAP Gateway aktivieren (/IWFND/IWF_ACTIVATE): SPRO -> SAP NetWeaver -> SAP Gateway -> OData Channel -> Konfiguration -> SAP Gateway aktivieren oder deaktivieren
  • SAP System Alias einrichten (SM30 + /IWFND/V_DFSYAL): SPRO -> SAP NetWeaver -> SAP Gateway -> OData Channel -> Konfiguration -> Verbindungseinstellungen -> SAP Gateway zu SAP-System -> SAP-Systemalias verwalten
  • SAP Gateway Einstellungen (SM30 + /IWBEP/C_SYSTEM): SPRO -> SAP NetWeaver -> Aktivierung SAP-Gateway-Service -> Backend OData Channel -> Verbindungsweinstellungen zu SAP Gateway -> SAP-Gateway-Einstellungen
  • Entwicklungspaket anlegen: Transportauftrag
  • bei mehreren Systemen: RFC-Verbindungen pflegen (SM59, SMT1)
  • Einrichtung Systemalias zu Service (/IWFND/MAINT_SERVICE): Transportauftrag
  • Frontend-Service aktivieren (SICF): sap/bc/ui5_ui5/sap/ -> aktivieren
  • Backend-Service aktivieren (SICF): sap/bc/bsp/sap/ -> aktivieren
  • Berechtigungen für Services einrichten (PFCG)
  • Frontend (Eclipse): Transportauftrag
  • Backend (SEGW, SE80): Transportauftrag

Weiterführende Infos: Quick Starter Configuration Guide – SAP Gateway

[ABAP] OData: $top und $skip – Pagingfunktionen implementieren

* für SAPUI5-Elemente muss zugehöriges EntitySet in der SEGW auf "Paginierbar" gestellt sein
METHOD xyz_get_entityset.

  ...

* $top und $skip auslesen
    DATA(lv_top) = io_tech_request_context->get_top( ).
    DATA(lv_skip) = io_tech_request_context->get_skip( ).
    DATA(lv_maxrows) = 0.

* lv_maxrows setzen
    IF lv_top > 0.
      lv_maxrows = lv_top + lv_skip.
    ENDIF.

* Daten holen
    SELECT * FROM abc INTO TABLE @et_entityset UP TO @lv_maxrows ROWS.

* überflüssige Daten löschen
    IF NOT lv_skip IS INITIAL.
      DELETE et_entityset TO lv_skip.
    ENDIF.

  ...

ENDMETHOD.

[ABAP] OData: $orderby implementieren

* https://blogs.sap.com/2013/09/03/sap-gw-implement-a-better-orderby-for-cust-ext-class/
* http://www.techippo.com/2016/08/sorting-query-options-orderby-sap-odata-service.html
* http://www.saplearners.com/orderby-query-option-in-sap-netweaver-gateway/

METHOD xyz_get_entityset.

  ...

  DATA(it_orderby) = io_tech_request_context->get_orderby( ).

  IF line_exists( it_orderby[ property = 'MATNR' ] ).
    DATA(lv_orderby) = it_orderby[ property = 'MATNR' ].

    CASE lv_orderby-order.
      WHEN 'asc'.
        SORT: et_entityset BY name ASCENDING.
      WHEN 'desc'.
        SORT: et_entityset BY name DESCENDING.
    ENDCASE.
  ENDIF.

  ...

ENDMETHOD.

[ABAP] OData: DELETE – Datensatz für eine Entität löschen

* URL
URL/SERVICENAME/ItemSet(Key1='...',Key2='...')
* METHODE: DELETE
* HTTP-Request: <leer->
* HTTP-Response: 204 / Deleted / Empty Response

METHOD xyz_delete_entity
  DATA: lv_entry_data TYPE zcl_xyz_mpc=>ts_pos.

* HTTP-Daten holen
  io_data_provider->read_entry_data( IMPORTING es_data = lv_entry_data ).

* Wenn Keywerte gefüllt
  IF NOT lv_entry_data-col1 IS INITIAL.

* Daten löschen
    DELETE FROM abc WHERE col1 = lv_entry_data-col1.

    IF sy-subrc <> 0.
* Exceptionhandling
      ...
    ENDIF.
  ENDIF.
ENDMETHOD.

[ABAP] OData: CREATE – Neuen Datensatz für eine Entität erzeugen

* URL
URL/SERVICENAME/ItemSet
* METHODE: POST
* HTTP-Request: Entität mit den Keyfeldern
* HTTP-Response: 201 / Created / Erzeugte Entität bei Erfolg
METHOD xyz_create_entity
  DATA: lv_entry_data TYPE zcl_xyz_mpc=>ts_pos.

* HTTP-Daten holen
  io_data_provider->read_entry_data( IMPORTING es_data = lv_entry_data ).

* Daten aufbereiten
  ...

* Datensatz anlegen
  INSERT INTO abc VALUES ...

  IF sy-subrc = 0.
* Rückgabemenge für erzeugten Datensatz aufbereiten
    er_entity ...
  ELSE.
* Exceptionhandling
    ...
  ENDIF.
ENDMETHOD.