Startseite Archive nach Kategorien "SAP" (Seite 113)

Kategorie: SAP

[ABAP] Monatsnamen ermitteln (sprachabhängig) 

DATA: it_month_names TYPE STANDARD TABLE OF t247.
DATA: rc TYPE sy-subrc.

CALL FUNCTION 'MONTH_NAMES_GET'
  EXPORTING
    language              = sy-langu
  IMPORTING
    return_code           = rc
  TABLES
    month_names           = it_month_names
  EXCEPTIONS
    month_names_not_found = 1
    OTHERS                = 2.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ELSE.
  IF rc = 0.
    LOOP AT it_month_names INTO DATA(wa).
      WRITE: / wa-spras, wa-mnr, wa-ktx, wa-ltx.
    ENDLOOP.
  ENDIF.
ENDIF.

[ABAP] Popup mit einspaltige Auswahl (Tabelle) anzeigen 

TYPES: BEGIN OF t_line,
         vorname TYPE char255,
         name    TYPE char255,
         age     TYPE i,
       END OF t_line.

DATA: it_selection TYPE STANDARD TABLE OF t_line.
DATA: lv_choise TYPE i.

it_selection = VALUE #( ( vorname = 'Horst' name = 'Lehmann' age = '70' )
                        ( vorname = 'Udo' name = 'Beyer' age = '50' )
                        ( vorname = 'Heinz' name = 'Schmidt' age = '50' ) ).

CALL FUNCTION 'POPUP_WITH_TABLE_DISPLAY'
  EXPORTING
    endpos_col   = 20
    endpos_row   = 20
    startpos_col = 3
    startpos_row = 3
    titletext    = 'Auswahl'
  IMPORTING
    choise       = lv_choise
  TABLES
    valuetab     = it_selection
  EXCEPTIONS
    break_off    = 1
    OTHERS       = 2.

IF sy-subrc <> 0.
ELSE.
  IF lv_choise EQ 0.
    WRITE 'Nichts ausgewählt.'.
  ELSE.
    WRITE: / 'Zeile: ', lv_choise.
    WRITE: / 'Wert:', it_selection[ lv_choise ]-name.
  ENDIF.
ENDIF.

[ABAP] BDC (Batch Data Communication / Batch-Input)

Transaktionsrecorder zur Aufzeichnung der Bedienschritte: SHDB

Variante 1 (Sofortige Ausführung über CALL TRANSACTION)

DATA: it_batchdata TYPE STANDARD TABLE OF bdcdata.
DATA: it_params TYPE STANDARD TABLE OF rfc_spagpa.
DATA: it_msg TYPE STANDARD TABLE OF bdcmsgcoll.
DATA: lv_mode TYPE sy-ftype.
DATA: lv_update TYPE sy-ftype.

* A = Ausführen im Vordergrund (Hell abspielen, mit Bestätigungen)
* E = Ausführen im Hintergrund, aber Stoppen bei Fehler (dunkel abspielen, bei Fehler hell)
* N = Ausführen im Hintergrund, sammeln Fehler in Fehlertabelle (dunkel abspielen), bei Break-Point Abbruch
* P = Ausführen im Hintergrund, sammeln Fehler in Fehlertabelle (dunkel abspielen), bei Break-Point Sprung in Debugger
lv_mode = 'A'.
* A = Asynchrone Verbuchung. Verbuchungen des aufgerufenen Programms werden so durchgeführt, als sei bei der Anweisung COMMIT WORK der Zusatz AND WAIT nicht angegeben.
* S = Synchrone Verbuchung. Verbuchungen des aufgerufenen Programms werden so durchgeführt, als sei bei der Anweisung COMMIT WORK der Zusatz AND WAIT angegeben.
* L = Lokale Verbuchung. Verbuchungen des aufgerufenen Programms werden durchgeführt, als sei in ihm die Anweisung SET UPDATE TASK LOCAL ausgeführt worden.
lv_update = 'A'.

it_batchdata = VALUE #( ( program = 'SAPMV45A' dynpro = '0102' dynbegin = 'X' fnam = '' fval = '' )        " Einstiegsbildschirm aufrufen
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_CURSOR' fval = 'VBAK-VBELN' ) " Einstiegsbildschirm aufrufen
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'VBAK-VBELN' fval = '122' )    " OK-Code übergeben
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_OKCODE' fval = '=SUCH' )
                        ( program = 'SAPMV45A' dynpro = '4001' dynbegin = 'X' fnam = '' fval = '' )
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_OKCODE' fval = '/EBABA' ) ).       " Bildschirm füllen

* ohne neuen Task und ohne Berechtigungsprüfungen starten
*CALL TRANSACTION 'VA03'
*  USING it_batchdata
*  MODE lv_mode
*  UPDATE lv_update
*  MESSAGES INTO it_msg.

* in neuem Task (Fenster) mit Berechtigungsprüfung starten
CALL FUNCTION 'ABAP4_CALL_TRANSACTION' STARTING NEW TASK 'PROGRAM_1'
  EXPORTING
    tcode                   = 'VA03'
    skip_screen             = abap_false
    mode_val                = lv_mode
    update_val              = lv_update
  TABLES
    using_tab               = it_batchdata
    spagpa_tab              = it_params
    mess_tab                = it_msg
  EXCEPTIONS
    call_transaction_denied = 1
    tcode_invalid           = 2
    OTHERS                  = 3.

CASE sy-subrc.
  WHEN 0.
    WRITE: / 'Ok.'.
  WHEN 1.
    WRITE: / 'call_transaction_denied'.
  WHEN 2.
    WRITE: / 'tcode_invalid.'.
  WHEN OTHERS.
    WRITE: / 'Other error.'.
ENDCASE.

LOOP AT it_msg ASSIGNING FIELD-SYMBOL(<fl_msg>).
  WRITE: / <fl_msg>-dyname.
ENDLOOP.

Variante 2 (neue Mappe, die in der Transaktion SM35 (Batch-Input: Mappenübersicht) eingesehen werden kann, erstellen)

DATA: t_bdcdata LIKE TABLE OF bdcdata.
DATA: fs_bdcdata LIKE LINE OF t_bdcdata.

* Mappe öffnen
CALL FUNCTION 'BDC_OPEN_GROUP'
  EXPORTING
    client              = sy-mandt
    group               = 'MAPPENNAME' " hier Namen der Mappe eintragen
    keep                = 'X'
    user                = sy-uname
  EXCEPTIONS
    client_invalid      = 1
    destination_invalid = 2
    group_invalid       = 3
    group_is_locked     = 4
    holddate_invalid    = 5
    internal_error      = 6
    queue_error         = 7
    running             = 8
    system_lock_error   = 9
    user_invalid        = 10
    OTHERS              = 11.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

* Batchdaten zur Mappe hinzufügen (Beispiel)
* z.B. Programmaufruf
CLEAR fs_bdcdata.
fs_bdcdata-program = 'SAPMM06B'.  " Programmname
fs_bdcdata-dynpro = '0100'.       " Dynpro
fs_bdcdata-dynbegin = 'X'.        " Screen start
APPEND fs_bdcdata TO t_bdcdata.

* z.B. Feldwerte eintragen
CLEAR fs_bdcdata.
fs_bdcdata-fnam = 'EBAN-BSART'.   " Feldname
fs_bdcdata-fval = fs_field-bsart. " Feldwert
CONDENSE fs_bdcdata-fval.
APPEND fs_bdcdata TO t_bdcdata.

* z.B. Aktion auslösen
CLEAR fs_bdcdata.
fs_bdcdata-fnam = 'BDC_OKCODE'.   " OK-Code
fs_bdcdata-fval = '/00'.          " Enter (z.B. '=BU' -> Save, '=SAV' -> Save, '=BACK' -> Zurück)
CONDENSE fs_bdcdata-fval.
APPEND fs_bdcdata TO t_bdcdata.

CALL FUNCTION 'BDC_INSERT'
  EXPORTING
    tcode            = 'ME51'
  TABLES
    dynprotab        = t_bdcdata
  EXCEPTIONS
    internal_error   = 1
    not_open         = 2
    queue_error      = 3
    tcode_invalid    = 4
    printing_invalid = 5
    posting_invalid  = 6
    OTHERS           = 7.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

* Mappe schließen
CALL FUNCTION 'BDC_CLOSE_GROUP'
  EXCEPTIONS
    not_open    = 1
    queue_error = 2
    OTHERS      = 3.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

Weiterführende Infos: Link

[ABAP] ALV – Auswahlpopup für Selektion einer Anzeigevariante anzeigen 

DATA: ls_variant LIKE disvariant.
DATA: lv_exit TYPE c.

PARAMETERS p_vari LIKE disvariant-variant.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_vari.

  CLEAR ls_variant.

  ls_variant-report = sy-repid.
  ls_variant-username = sy-uname.

  CALL FUNCTION 'REUSE_ALV_VARIANT_F4'
    EXPORTING
      is_variant    = ls_variant
      i_save        = 'A'
    IMPORTING
      e_exit        = lv_exit
      es_variant    = ls_variant
    EXCEPTIONS
      not_found     = 1
      program_error = 2
      OTHERS        = 3.

  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ELSE.
    IF lv_exit EQ space.
      p_vari = ls_variant-variant.
    ENDIF.
  ENDIF.

[ABAP] Prüfen, ob string eine Zahl (numerisch) ist 

* erlaubte Zeichen für numerischen String
CONSTANTS: c_numeric TYPE string VALUE '-., 0123456789'.

DATA: val_in TYPE string VALUE '    -123.2'.

* funktioniert nicht mit strings wie '0.0.1' usw.
* CO -> contains only
IF val_in CO c_numeric.
  WRITE: / |String "{ val_in }" ist numerisch.|.
ELSE.
  WRITE: / |String "{ val_in }" ist nicht numerisch.|.
ENDIF.

[ABAP] Klasse (cl_s_aut_bal_log) zur Verwendung des Business Application Log (BAL) 

* cl_s_aut_bal_log implementiert die gundlegenden Funktionen (FuBas) des Application-Log
* Es werden z.B. NICHT implementiert: BAL_DB_SEARCH, BAL_DB_LOAD.
* Es kann nicht mit Verfallsdatum gearbeitet werden.
START-OF-SELECTION.
* Legt eine Protokoll-Instanz an
* Log-Objekte werden in der Transaktion SLG0 definiert --> es werden Transportaufträge generiert
* Anlegen der Objekte erfolgt in den Tabellen
*   BALOBJ (Anwendungs-Log: Objekte)
*   BALSUB (Anwendungs-Log: Unterobjekte)
  DATA(o_applog) = cl_s_aut_bal_log=>create( im_object    = 'Z_TEST_LOG'
                                             im_subobject = 'Z_TEST_LOG_U1' ).

* Protokolleinträge hinzufügen -> Nachrichten werden in der Transaktion SE91 gefplegt
* Beispiel: Verwendung der vordefinierten Nachrichtenklasse 'S_AUT', Nr. '128'
  o_applog->add_entry( im_msgtype = 'I'
                       im_msgid   = 'S_AUT'
                       im_msgno   = '128' ).

* Beispiel: Verwendung der generische Nachrichtenklasse mit & & & & für die Parameter msgv1 - msgv4
  o_applog->add_entry( im_msgtype = 'W'
                       im_msgid   = '01'
                       im_msgno   = '319'
                       im_msgv1   = 'Test1'
                       im_msgv2   = 'Test2'
                       im_msgv3   = 'Test3'
                       im_msgv4   = 'Test4' ).

  TRY.
* Ausnahme auslösen
      DATA(result) = 1 / 0.

    CATCH cx_root INTO DATA(e_txt).
* Fügt eine Ausnahme hinzu, wobei
* im_probclass: 1 - sehr wichtig
*               2 - wichtig
*               3 - mittel
*               4 - Zusatzinformationen
      o_applog->add_exception( im_probclass = '4'
                               im_msgtype = 'E'
                               im_exception = e_txt ).
  ENDTRY.

* Existieren Meldungen?
  IF o_applog->has_statistic( ) = abap_true.
* Protokoll anzeigen
    o_applog->show( im_title = 'Application-Log' ).
  ENDIF.

* Schließt und persistiert (speichert) das Protokoll
* Protokoll kann in der Transaktion SLG1 angeschaut werden
* Speicherung der Log-Daten erfolgt in den Tabellen
*   BALHDR (Anwendungs-Log: Protokollkopf)
*   BALDAT (Anwendungs-Log: Daten eines Protokolls)
  o_applog->close( im_save = CONV #( abap_true ) ).

Weiterführende Infos: Link, Link, Link und Link

[ABAP] Formeleditor 

Beispielprogramm        Bedeutung

SFBE_EXAMPLE1           Beispielprogramm FoBuEv: Einfachst-Aufruf 
SFBE_EXAMPLE2           Beispielprogramm FoBuEv: Aufruf mit eigenen Feldern 
SFBE_EXAMPLE3           Beispielprogramm FoBuEv: Aufruf mit Typprüfung, eigenem GUI-Status und TraceDer Trace wird im Menü eingeschaltet! 
SFBE_EXAMPLE4           Beispielprogramm FoBuEv: Aufruf mit eigenen Funktionen 
SFBE_EXAMPLE5           Beispielprogramm FoBuEv: Implementierung einer Methode per FoBuEv 
SFBE_EXAMPLE6           Beispielprogramm FoBuEv: Aufruf mit eigenen Drucktasten und IF-Funktion 
SFBE_EXAMPLE8           Beispielprogramm FoBuEv: Rechnen mit Währungsbeträgen, Mengen und Preisen
RS_FOBU_METHOD_EXAMPLE  Beispielprogramm für Formula Builder Methoden

wichtige Klassen:

cl_fobu_formula
cl_foev_formula
cl_fobu_connector

Weiterführende Infos: Link

[ABAP] Detaildaten eines Benutzers lesen 

DATA: ls_address TYPE bapiaddr3.
DATA: ls_admindata TYPE bapiuseradmin.
DATA: ls_userdefault TYPE bapidefaul.
DATA: ls_company TYPE bapiuscomp.
DATA: lt_message TYPE bapirettab.

" Userdaten auslesen
CALL FUNCTION 'BAPI_USER_GET_DETAIL'
  EXPORTING
    username  = sy-uname
  IMPORTING
    address   = ls_address
    admindata = ls_admindata
    company   = ls_company
    defaults  = ls_userdefault
  TABLES
    return    = lt_message.

" einige der gelesenen Daten ausgeben
WRITE: / ls_address-firstname.
WRITE: / ls_address-lastname.
WRITE: / ls_address-e_mail.

WRITE: / ls_admindata-aname.

WRITE: / ls_company-company.