Start SAP Archiv nach Kategorie "ABAP"

Kategorie: ABAP

[ABAP] SALV: Events abfangen beim Klick auf die ALV Funktions-Buttons am Beispiel Filter-Setzen 

CLASS lcl_salv DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: on_before_function FOR EVENT before_salv_function OF cl_salv_events_table
      IMPORTING e_salv_function
                sender.

    CLASS-METHODS: on_after_function FOR EVENT after_salv_function OF cl_salv_events_table
      IMPORTING e_salv_function
                sender.
ENDCLASS.

CLASS lcl_salv IMPLEMENTATION.
* Event vor ALV-Button Klick
  METHOD on_before_function.
* Werte für e_salv_function sind in cl_salv_gui_ui_function_tools=>cs_list_ui_function deklariert
    CASE e_salv_function.
* '&ETA'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-detail.
        MESSAGE |Details { e_salv_function }| TYPE 'S'.
* '&ILT'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-filter.
        MESSAGE |Filter { e_salv_function }| TYPE 'S'.
* '%PC'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-system_localfile.
        MESSAGE |Export { e_salv_function }| TYPE 'S'.
      WHEN OTHERS.
        MESSAGE |Before Other { e_salv_function }| TYPE 'S'.
    ENDCASE.
  ENDMETHOD.

* Event nach ALV-Button Klick
  METHOD on_after_function.
* Werte für e_salv_function sind in cl_salv_gui_ui_function_tools=>cs_list_ui_function deklariert
    CASE e_salv_function.
* '&ETA'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-detail.
        MESSAGE |Details { e_salv_function }| TYPE 'S'.
* '&ILT'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-filter.
        MESSAGE |Filter { e_salv_function }| TYPE 'S'.
* '%PC'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-system_localfile.
        MESSAGE |Export { e_salv_function }| TYPE 'S'.
      WHEN OTHERS.
        MESSAGE |After Other { e_salv_function }| TYPE 'S'.
    ENDCASE.
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.

  SELECT FROM mara
    FIELDS *
    INTO TABLE @DATA(it_mara)
    UP TO 10 ROWS.

    try.
* SALV-Table
  DATA: o_salv TYPE REF TO cl_salv_table.

  cl_salv_table=>factory( IMPORTING r_salv_table = o_salv
                          CHANGING  t_table      = it_mara ).

* Grundeinstellungen
  o_salv->get_functions( )->set_all( abap_true ).
  o_salv->get_columns( )->set_optimize( abap_true ).
  o_salv->get_display_settings( )->set_list_header( 'Überschrift' ).
  o_salv->get_display_settings( )->set_striped_pattern( abap_true ).
  o_salv->get_selections( )->set_selection_mode( if_salv_c_selection_mode=>row_column ).

* Spaltenüberschriften: technischer Name und Beschreibungstexte, Short Text und Medium Text leer lassen für Autosize
  LOOP AT o_salv->get_columns( )->get( ) ASSIGNING FIELD-SYMBOL(<c>).
    DATA(o_col) = <c>-r_column.
    o_col->set_short_text( || ).
    o_col->set_medium_text( || ).
    o_col->set_long_text( |{ o_col->get_columnname( ) } [{ o_col->get_long_text( ) }]| ).
  ENDLOOP.

* Event-Handler für Klick auf die ALV-Funktionsbuttons (Sort, Filter, Export...)
  SET HANDLER lcl_salv=>on_before_function FOR o_salv->get_event( ).
  SET HANDLER lcl_salv=>on_after_function FOR o_salv->get_event( ).

  o_salv->display( ).
CATCH cx_root INTO DATA(e_txt).
  WRITE: / e_txt->get_text( ).
ENDTRY.

[ABAP] Leistungsverzeichnis mit Gliederung zu einem Einkaufsbeleg lesen 

PARAMETERS: p_ebeln TYPE ekpo-ebeln.

START-OF-SELECTION.

  SELECT SINGLE FROM ekpo
    FIELDS
      menge,
      meins,
      bprme,
      netpr,
      peinh,
      txz01,
      packno
    WHERE ebeln EQ @p_ebeln
      AND ebelp EQ '00001'
    INTO @DATA(lv_ekpo).

  IF sy-subrc EQ 0.
    DATA: it_gliederung TYPE STANDARD TABLE OF ml_esll WITH DEFAULT KEY.

* Holen Gliederungsdaten für Listausgabe
    CALL FUNCTION 'MS_SUBDIVISION_FOR_PRINT'
      EXPORTING
        packno           = lv_ekpo-packno
      TABLES
        gliederung       = it_gliederung
      EXCEPTIONS
        packno_not_exist = 1
        OTHERS           = 2.

    IF sy-subrc = 0.

      DATA: it_leistung TYPE STANDARD TABLE OF ml_esll WITH DEFAULT KEY.

      LOOP AT it_gliederung ASSIGNING FIELD-SYMBOL(<g>).

        DATA(pos) = ( <g>-rang * 2 ).

        IF <g>-rang = 0.
          WRITE: AT /pos '#', lv_ekpo-txz01, lv_ekpo-menge, lv_ekpo-meins, lv_ekpo-netpr.
        ELSE.
          WRITE: AT /pos '#', <g>-ktext1.
        ENDIF.

        CLEAR: it_leistung.

* Holen Leistungen für Listanzeige
        CALL FUNCTION 'MS_SERVICES_FOR_PRINT'
          EXPORTING
            packno            = <g>-sub_packno
          TABLES
            leistung          = it_leistung
          EXCEPTIONS
            no_services_found = 1
            OTHERS            = 2.

        IF sy-subrc = 0.
          LOOP AT it_leistung ASSIGNING FIELD-SYMBOL(<l>).
            WRITE: AT /10 <l>-extrow, '|', <l>-srvpos, '|', <l>-menge, <l>-meins, <l>-brtwr, <l>-waers, <l>-ktext1, '|', <l>-ebeln, <l>-ebelp.
          ENDLOOP.
        ENDIF.

        WRITE: /.

      ENDLOOP.

    ENDIF.
  ENDIF.

[ABAP] SPRO-Customizing Strukturen anzeigen 

* TTREE-IDs stehen in Tabelle TTREE (Definitionstabelle für Strukturen) + TTREET (Bezeichung einer Struktur)
* Hier als Beispiel vorbelegt mit 5BB3C2F5329FD21195360060B03C6B76 für Knoten 'Logistik Allgemein'
DATA: lv_img_id type ttree-id VALUE '5BB3C2F5329FD21195360060B03C6B76'.

* Lesen der ID für den Referenz-IMG
* SPRO-ID aus der Tabelle SCUS_HIER (Ersetzungstabelle für Hierarchien)
CALL FUNCTION 'S_CUS_IMG_GET_REFERENCE_IMG_ID'
  IMPORTING
    reference_img_id = lv_img_id.

* Anzeigeattribute der Hierarchiepflege
DATA(it_user_parameters) = VALUE streeprop_t( ( name = 'APPLICATION'     value = 'CU' )
                                              ( name = 'CONTROL_ENABLED' value = abap_true )
                                              ( name = 'DYNPRO_TITLE'    value = 'Überschrift' ) ).

* Anzeige einer Struktur
CALL FUNCTION 'STREE_EXTERNAL_DISPLAY'
  EXPORTING
    structure_id    = lv_img_id
  TABLES
    user_parameters = it_user_parameters.

Links

[ABAP] Sichten zu einem Material anzeigen 

PARAMETERS: p_mat TYPE mara-matnr.

START-OF-SELECTION.

* Status definieren
  SELECT FROM t132 AS t
    LEFT OUTER JOIN t132t AS tt ON t~statm = tt~statm
    FIELDS
      t~statm,
      t~kzdum,
      tt~sttxt
    WHERE tt~spras = @sy-langu
    INTO TABLE @DATA(it_t132).

* Werksdaten zum Material
  SELECT FROM marc
    FIELDS
      matnr,
      werks,
      pstat
    WHERE matnr EQ @p_mat
    ORDER BY werks
    INTO TABLE @DATA(it_marc).

* Materialstammstatus
  SELECT FROM msta
    FIELDS *
    WHERE matnr EQ @p_mat
    ORDER BY werks
    INTO TABLE @DATA(it_msta).

* Daten im Inline-Browser im SAP-Fenster anzeigen
  cl_abap_browser=>show_html( EXPORTING
                                title        = 'Sichten zum Material'
                                html_string  = cl_demo_output=>new( )->write_data( it_t132 )->write_data( it_marc )->write_data( it_msta )->get( )
                                container    = cl_gui_container=>default_screen ).

* cl_gui_container=>default_screen erzwingen
  WRITE: space.

[ABAP] Geschäftspartner (Business Partner) in der Transaktion BP anzeigen

Variante 1: Anzeige über Partnernummer


PARAMETERS: p_bp TYPE bapibus1006_head-bpartner.

START-OF-SELECTION.

  IF NOT p_bp IS INITIAL.

* SAP-GP Dialog: Navigationscommando
    DATA(o_req) = NEW cl_bupa_navigation_request( ).
* Partnernummer setzen, analog zu set_partner_guid( )
    o_req->set_partner_number( p_bp ).
* Setzt die aktive Pflege (Einstieg, Partnerdaten, Beziegungen)
    o_req->set_maintenance_id( iv_value = cl_bupa_navigation_request=>gc_maintenance_id_partner ).
* Aktivität zur Anzeige / Pflege der Geschäftspartnerdaten
    o_req->set_bupa_activity( iv_value = cl_bupa_navigation_request=>gc_activity_display ).
* Setzt den aktiven Tabreiter der Geschäftspartnerpflege
*    o_req->set_bupa_sub_header_tab( 'CVIC01' ). " Tabelle TBZ3A, Objekt BUPA
* Setzt die Geschäftspartnerrolle für die Geschäftspartnerpflege
*    o_req->set_bupa_partner_role( VALUE #( role = 'FS0000' ) ). " Tabelle TB003

* SAP-GP Dialog: Startoptionen für die Pflegeoberfläche
    DATA(o_options) = NEW cl_bupa_dialog_joel_options( ).
* Setzt die Sichtbarkeit des Locators
    o_options->set_locator_visible( space ).

* Macht das Navigieren zu anderen Partnern unmöglich
*    o_options->set_navigation_disabled( abap_true ).
* Setzt das Kennzeichen für 'Anlegen von Beziehungen' erlaubt
*    o_options->set_bupr_create_not_allowed( abap_true ).
* Macht das Navigieren zu anderen Rollen unmöglich
*    o_options->set_role_switching_disabled( abap_true ).
* Maintenance
*    o_options->set_bupr_maintenance( VALUE #( create_allowed = abap_true
*                                              change_allowed = abap_true
*                                              delete_allowed = abap_true ) ).
* Macht das Navigieren zu einer anderen Aktivität unmöglich
*    o_options->set_activity_switching_off( space ).

* Startmethode für Aufrufe aus anderen Anwendungen
    cl_bupa_dialog_joel=>start_with_navigation( iv_request              = o_req
                                                iv_options              = o_options
                                                iv_in_new_internal_mode = abap_true ).
  ENDIF.

Variante 2: Anzeige über GUID des Business-Partners

PARAMETERS: p_bp TYPE bapibus1006_head-bpartner.

START-OF-SELECTION.

  IF NOT p_bp IS INITIAL.

* GP: Allgemeine Daten I
* BP-GUID zur Partnernummer holen
    SELECT SINGLE FROM but000
      FIELDS partner_guid
      WHERE partner = @p_bp
      INTO @DATA(lv_bp_guid).

    IF lv_bp_guid IS NOT INITIAL.
* SAP-GP Dialog: Navigationscommando
      DATA(o_req) = NEW cl_bupa_navigation_request( ).
      o_req->set_partner_guid( lv_bp_guid ).
      o_req->set_maintenance_id( iv_value = cl_bupa_navigation_request=>gc_maintenance_id_partner ).
      o_req->set_bupa_activity( iv_value = cl_bupa_navigation_request=>gc_activity_display ).

* SAP-GP Dialog: Startoptionen für die Pflegeoberfläche
      DATA(o_options) = NEW cl_bupa_dialog_joel_options( ).
      o_options->set_locator_visible( space ).

* Startmethode für Aufrufe aus anderen Anwendungen
      cl_bupa_dialog_joel=>start_with_navigation( iv_request              = o_req
                                                  iv_options              = o_options
                                                  iv_in_new_internal_mode = abap_true ).
    ENDIF.
  ENDIF.

Links

[ABAP] Informationen zu einer Einkäufergruppe als Popup anzeigen 

PARAMETERS: p_ekgrp TYPE t024-ekgrp.

START-OF-SELECTION.

  SELECT FROM t024
    FIELDS *
    WHERE ekgrp EQ @p_ekgrp
    INTO TABLE @DATA(it_t024).

  IF sy-subrc = 0.

    TRY.
        DATA: o_pop_ekgrp TYPE REF TO cl_salv_table.

        cl_salv_table=>factory( IMPORTING r_salv_table = o_pop_ekgrp
                                CHANGING  t_table      = it_t024 ).

        o_pop_ekgrp->get_functions( )->set_all( abap_true ).
        o_pop_ekgrp->get_columns( )->set_optimize( abap_true ).
        o_pop_ekgrp->get_display_settings( )->set_list_header( 'Einkäufergruppe' ).
        o_pop_ekgrp->get_display_settings( )->set_striped_pattern( abap_true ).
        o_pop_ekgrp->get_selections( )->set_selection_mode( if_salv_c_selection_mode=>row_column ).

        o_pop_ekgrp->set_screen_popup( start_column = 1
                                       end_column   = 140
                                       start_line   = 1
                                       end_line     = 20 ).
        o_pop_ekgrp->display( ).
      CATCH cx_root INTO DATA(e_txt).
        WRITE: / e_txt->get_text( ).
    ENDTRY.

  ENDIF.

[ABAP] Adressdaten lesen 

* Adressnummer mit führenden Nullen
PARAMETERS: p_adr TYPE adrc-addrnumber.

START-OF-SELECTION.

  DATA(lv_addr1_sel) = VALUE addr1_sel( addrnumber = p_adr ).
  DATA(lv_addr1_val) = VALUE addr1_val( ).

  CALL FUNCTION 'ADDR_GET'
    EXPORTING
      address_selection = lv_addr1_sel
    IMPORTING
      address_value     = lv_addr1_val
    EXCEPTIONS
      parameter_error   = 1
      address_not_exist = 2
      version_not_exist = 3
      internal_error    = 4
      OTHERS            = 5.

  IF sy-subrc = 0.
* Daten im Inline-Browser im SAP-Fenster anzeigen
    cl_abap_browser=>show_html( EXPORTING
                                  title        = 'Adressdaten'
                                  html_string  = cl_demo_output=>new( )->write_data( lv_addr1_sel )->write_data( lv_addr1_val )->get( )
                                  container    = cl_gui_container=>default_screen ).

* cl_gui_container=>default_screen erzwingen
    WRITE: space.
  ENDIF.

Links

[ABAP] Adressdaten anzeigen 

* Adressnummer mit führenden Nullen
PARAMETERS: p_adr TYPE adrc-addrnumber.

START-OF-SELECTION.

  DATA: lv_okcode TYPE sy-ucomm.
  DATA: it_handle TYPE STANDARD TABLE OF addr1_dia WITH NON-UNIQUE DEFAULT KEY.
  DATA: it_values TYPE STANDARD TABLE OF addr1_data WITH DEFAULT KEY.

* Adressgruppe aus der ADRC holen
  SELECT SINGLE FROM adrc
    FIELDS addr_group
    WHERE addrnumber EQ @p_adr
    INTO @DATA(lv_adr_grp).

  it_handle = VALUE #( ( addrnumber = p_adr      " Adressnummer aus er ADRC
                         maint_mode = 'DISPLAY'  " Daten nur anzeigen, weitere Modi sind 'CREATE' und 'CHANGE'
                         country    = 'DE'       " Ausgabeformat
                         addr_group = lv_adr_grp " siehe Tabelle TSAD7 (Adreßgruppen (Business Address Services))
                       ) ).

* Dialogpflege von Adressen
  CALL FUNCTION 'ADDR_DIALOG'
    IMPORTING
      ok_code           = lv_okcode
    TABLES
      number_handle_tab = it_handle
      values            = it_values
    EXCEPTIONS
      address_not_exist = 1
      group_not_valid   = 2
      parameter_error   = 3
      internal_error    = 4
      OTHERS            = 5.

  IF sy-subrc = 0.
* Daten im Inline-Browser im SAP-Fenster anzeigen
    cl_abap_browser=>show_html( EXPORTING
                                  title        = 'Adressdaten'
                                  html_string  = cl_demo_output=>new( )->write_data( lv_okcode )->write_data( it_values )->get( )
                                  container    = cl_gui_container=>default_screen ).

* cl_gui_container=>default_screen erzwingen
    WRITE: space.
  ENDIF.

Links

[CDS-Views] Übersicht zu nützlichen CDS-Views

ObjekteCDS-ViewKurzbezeichnungBemerkung
AdresseI_AddressAddressADCP, ADRC
AdresseI_Address_2Address of an Organization or a PersonADRP, ADCP, ADRC
ÄnderungsbelegeI_InvgCsMChangeLogICM Change LogCDHDR, CDPOS
AuftragI_OrderOrder HeaderAUFK, AFKO
AuftragI_OrderItemOrder ItemAFPO
AuftragI_SalesOrderSales OrderVBKD, VEDA, VBAK
AuftragI_SalesOrderItemSales Order ItemVBAP, VBAK, VBKD, VEDA
AuftragI_SalesDocumentSales DocumentVBKD, VEDA, VBAK
AuftragI_SalesDocumentItemSales Document ItemVBAP, VBAK, VBKD, VEDA
AuftragI_SalesOrderCubeSales Order – CubeVBAP, VBKD, VEDA, VBAK, FPLT, VBEP
BenutzerI_UserUserUSR21
BestellanforderungA_PurchaseRequisitionItemItemEBAN
BestellanforderungI_PurchaserequisitionitemPurchase Requisition ItemEBAN
BestellanforderungA_PurReqnAcctAssgmtAccount AssignmentEBAN, EBKN
BestellanforderungI_PurchaseReqnItemPurchase Requisition ItemsEBAN
BestellanforderungI_PurchaserequisitionPurchase Requisition HeaderEBAN
BestellungA_PurchaseOrderPurchase OrderEKKO
BestellungI_PurchaseOrderEnhancedPurchase Order enhancedEKKO, EKPO, EKET, EKBE
BestellungA_PurchaseOrderItemItemEKKO, EKPO
BestellungI_PurchaseorderItemEnhancedPurchase Order Item enhancedEKKO, EKPO, EKET, EKBE
BestellungI_PurchaseOrderItemAPI01Purchase Order ItemEKKO, EKPO
BestellungC_PurchaseOrderItemMoniMonitor Purchase Order ItemsEKKO, EKPO, EKET, EKES, EKBE
BestellungA_PurOrdAccountAssignmentAccount AssignmentEKKO, EKPO, EKKN
BestellungI_PurOrdAccountAssignmentPurchase Order Account AssignmentEKKO, EKPO, EKKN
BestellungC_PurchaseorderitemacctmntrPurchase Order Items by Account AssignmentEKKO, EKPO, EKKN, EKET, EKBE, AFKO
BestellungI_PurchasingDocumentItemPurchasing Document ItemEKKO, EKPO
BestellungC_PoItemMoniCalcFieldCalculation field for Monitor POEKKO, EKPO, EKBE
BestellungR_POItemNextDeliveryCalcPO Item Next Delivery CalculationEKKO, EKPO, EKET
BestellungA_PurchaseOrderScheduleLineSchedule LinesEKKO, EKPO, EKET
BestellungI_PurchaseOrderScheduleLinePurchase Order Schedule LineEKKO, EKPO, EKET
BestellungI_PurgDocScheduleLinePurchasing Document Schedule LineEKET
BestellungI_PurchaseOrderHistoryBasicPurchase Order HistoryEKKO, EKPO, EKBE
BestellungI_PurchaseOrderHistoryPurchase Order HistoryEKKO, EKPO, EKBE
BestellungI_POSubcontractingCompAPI01Subcontracting Component in PurOrdEKKO, RESB
BestellungI_PurOrdPricingElementPurchase Order Pricing ElementEKKO, PRCD_ELEMENTS
BestellungI_SupplierPurchasingOrgSupplier Purchasing OrganizationLFA1, LFM1
BewertungskreisI_ValuationAreaValuation AreaT001K
BuchhaltungsbelegI_JournalEntryJournal EntryBKPF
BuchhaltungsbelegI_JournalEntryItemJournal Entry ItemACDOCA, FINSC_LEDGER_REP
BuchungskreisI_CompanyCodeCompany CodeT001
ControllingI_ControllingCommitmentCommitment for ControllingCOOI
ControllingI_ControllingCommitmentLineItmCommitment Line Item ControllingCOOI, CSKS
DictionaryRsodp_Abap_Cds_View2stobABAP CDS: Name of SQL View and Structure ObjectDDLDEPENDENCY
DictionaryVfs_Object_SearchSearchTTREE, BADI_SPOT, TDEVC, TADIR, DD021, SEDT_PROGRAM, SEDT_FUNC, SEDT_WDYN, V_DDLDEP, WDY_COMPONENT
Dictionaryris_quick_search_viewQuick Search: Ctrl.+Shift.+ATTREE, BADI_SPOT, TDEVC, TADIR, DD021, SEDT_PROGRAM, SEDT_FUNC, SEDT_WDYN, V_DDLDEP, WDY_COMPONENT
Dokumenteninfosatzshsm_drad_drawValue help for search help CV01ODRAD, DRAW
DokumenteninfosatzP_DocumentInfoRecordAttachmentDocument Info Record AttachmentDMS_DOC2LOIO, DMS_PHIO2FILE, DMS_PH_CHKO_CD1, DMS_DOC_FILES, DMS_PHF_CD1, DMS_PH_CD1
DokumenteninfosatzA_DocumentInfoRecordAttchAttachments for Document Info RecordDRAT, TDWS, TDWST, DOST, DRAW
DokumenteninfosatzP_DocInfoRecdOriginalOriginals Of Document Info RecordsDMS_DOC2LOIO, DMS_PHIO2FILE, DMS_PH_CHKO_CD1, DMS_DOC_FILES, DMS_PHF_CD1, DMS_PH_CD1
EinkäufergruppeI_PurchasingGroupPurchasing GroupT024
EinkaufsinfosatzM_V_inforecordInforecordEINA, EINE
EinkaufsinfosatzI_PurchasingInfoRecordApi01Purchasing Info RecordEINA
EinkaufsinfosatzI_PurgInfoRecdOrgPlntDataApi01Org Plant Data for Purch Info RecordEINE
FioriCDS_SUI_TM_MM_CATCDS View for Catalogs
FioriCDS_SUI_TM_MM_APPCDS View for App Descriptor Items
GeschäftspartnerI_BusinessPartnerBusiness PartnerBUT000
GeschäftspartnerI_CustomerCustomerKNA1
GeschäftspartnerI_SupplierSupplierLFA1
Kalender, DatumI_CalendarDateDateSCAL_TT_DATE
Klassen, MerkmaleI_ClfnCharcBasicClassification Characteristic BasicCABN
Klassen, MerkmaleI_CharacteristicCharacteristicCABN
Klassen, MerkmaleI_RelstartcharCharacteristic Basic ViewCABN, CABNT
Klassen, MerkmaleI_ClassHeaderClass HeaderKLAH
Klassen, MerkmaleI_ClfnClassClassification ClassKLAH
Klassen, MerkmaleI_RelstratclassManage Class Basic ViewKLAH, SWOR
KontraktI_PurchaseContractPurchase ContractEKKO
KontraktA_PurchaseContractItemItemEKKO, EKPO
KontraktI_PurchaseContractItemPurchase Contract ItemEKKO, EKPO
KontraktI_PurContrAccountAssgmtPurchase Contract Account AssignmentEKKO, EKPO, EKKN
KontraktI_PurContrValidityStatusPurchase Contract Validity StatusEKKO, EKPO, EKAB
KontraktI_PurCtrAddressAddress For Contract ItemEKKO, EKPO, ADCP, ADRC
KostenrechnungskreisI_ControllingAreaControlling AreaTKA01, T000
LagerortI_StorageLocationStorage LocationT001L
LeistungserfassungI_ServiceEntrySheetService Entry SheetEKKO, EKPO, EKET
LeistungserfassungI_ServiceEntrySheetItemService Entry Sheet ItemEKKO, EKPO, EKET, MARA
LieferbelegI_DeliveryDocumentDelivery DocumentLIKP
LieferbelegI_DeliveryDocumentItemDelivery Document ItemLIKP, LIPS
MaterialI_SlowOrNonMovingMatlCubeSlow or Non-Moving MaterialsMATDOC, MARA, MAKT, CKMLCR, VBKD, VEDA, VBAK
MaterialA_ProductPlantPlant DataMARA, MARC
MaterialI_ProductPlantProduct PlantMARA, MARC
MaterialI_MaterialMaterialMARA
MaterialI_ProductProductMARA
MaterialI_MaterialInclStorLocationMaterial including Storage LocationMARA, MARC, MARD
MaterialI_MaterialStockMaterial Stock CalculationMATDOC
MaterialI_MaterialValuationPricesMaterial Valuation PricesCKMLCR, CKMLHD, PRPS, CKMLPR
MaterialI_ProductValuationTP_2Product Valuation - TP
MaterialI_ProdValnLedgerAccountTP_2Product Valuation Ledger Account - TP
MaterialI_ProdValuationAccountingTP_2Product Valuation Accounting - TP
MaterialI_ProductPlantTP_2Product Plant - TP
MaterialI_MaterialGroupTextMaterial Group TextT023, T023T
MaterialI_ProductUnitsOfMeasureUnits of Measure of ProductMARA, MARM
MaterialbelegeI_MaterialDocumentHeader_2Material Document HeaderMATDOC
MaterialbelegeI_MaterialDocumentItem_2Material Document ItemMATDOC
MengeneinheitenI_UnitOfMeasureUnit of MeasureT006, T006A
Profit CenterSHSM_PROFITCENTER_VHProfit Center Value HelpCEPC, CEPCT
ProjektI_ProjectProject Definition DetailsPROJ
PSP-ElementI_MM_WBSElementValueHelpPurchasing WBS Element Value HelpPROJ, PRPS
PSP-ElementI_WBSElementWBS Element DetailsPRTE, PROJ, PRPS
ReservierungI_ReservationDocumentHeaderReservation Document HeaderRKPF
ReservierungI_ReservationDocumentItemReservation Document ItemRKPF, RESB
SAPscriptI_TextObjectText ObjectSTHX, STXL
VertriebI_SalesDocumentSales DocumentVBKD, VEDA, VBAK
WährungI_CurrencyCurrencyTCURC, TCURX
WerkI_PlantPlantT001W
Werk, Buchungskreis, KostenrechnungskreisP_Kkag_Werk_Bukrs_KokrsPlant - Company Code - Co AereaT001K, T001W, TKA02
Werk, EinkaufsorganisationC_MM_PlantValueHelpPlant Value HelpT001W, T024E
WorkflowC_WorkflowtaskDEPRECATED: Work item with text infoSWWWIHEAD, SWPSTEPLOG, SWWWITEXT
WorkflowI_WorkflowTaskWorkflow work itemsSWWWIHEAD, SWPSTEPLOG, SWWWICOMMENT

Links

erp-up.de

  • ABAP Cloud: Die wichtigsten CDS Views

SAP API für CDS-Views

  • SAP-Standard CDS Views suchen

SAP Virtuelles Datenmodell und CDS-Views

  • Dokumentation von CDS-Views über verschiedene Geschäftsbereiche

paspas.io

  • Datenquellen (CDS-Views, Tabellen) finden