Startseite SAP ABAP Archive nach Kategorien "Funktionsbausteine" (Seite 8)

Kategorie: Funktionsbausteine

[ABAP] Angemeldete Benutzer eines Application-Servers auflisten 

DATA: it_uinfo TYPE TABLE OF uinfo.
DATA: it_usrinfo TYPE TABLE OF usrinfo.

CALL FUNCTION 'TH_USER_LIST'
  TABLES
    list = it_uinfo       " wenn auskommentiert, dann wird usrlist zurückgegeben, sonst nur list
    usrlist = it_usrinfo.

LOOP AT it_uinfo INTO DATA(wa_uinfo).
  WRITE: / wa_uinfo-tid,
          wa_uinfo-mandt,
          wa_uinfo-bname,
          wa_uinfo-tcode,
          wa_uinfo-term,
          wa_uinfo-zeit,
          wa_uinfo-master,
          wa_uinfo-hostadr,
          wa_uinfo-trace,
          wa_uinfo-extmodi,
          wa_uinfo-intmodi,
          wa_uinfo-type,
          wa_uinfo-stat,
          wa_uinfo-protocol,
          wa_uinfo-guiversion,
          wa_uinfo-rfc_type.
ENDLOOP.

LOOP AT it_usrinfo INTO DATA(wa_usrinfo).
  WRITE: / wa_usrinfo-tid,
          wa_usrinfo-mandt,
          wa_usrinfo-bname,
          wa_usrinfo-tcode,
          wa_usrinfo-term,
          wa_usrinfo-zeit,
          wa_usrinfo-master,
          wa_usrinfo-trace,
          wa_usrinfo-extmodi,
          wa_usrinfo-intmodi,
          wa_usrinfo-type,
          wa_usrinfo-stat,
          wa_usrinfo-protocol,
          wa_usrinfo-guiversion,
          wa_usrinfo-rfc_type,
          wa_usrinfo-hostaddr.
ENDLOOP.

[ABAP] Tag, Monat, Jahr zu Datumswert zusammenfügen 

DATA: lv_date TYPE sy-datum.
DATA: lv_i_day TYPE cms_dte_oms_day.
DATA: lv_i_month TYPE cms_dte_oms_month.
DATA: lv_i_year TYPE cms_dte_oms_year.

lv_i_day = 01.
lv_i_month = 06.
lv_i_year = 2016.

CALL FUNCTION 'CMS_API_GENERAL_DDMMYY_TO_DATE'
  EXPORTING
    i_day   = lv_i_day
    i_month = lv_i_month
    i_year  = lv_i_year
  IMPORTING
    e_date  = lv_date.

[ABAP] Datumswert in Tag, Monat, Jahr zerlegen 

DATA: lv_day TYPE char2.
DATA: lv_month TYPE char2.
DATA: lv_year TYPE char4.
DATA: lv_stext TYPE t247-ktx.
DATA: lv_ltext TYPE t247-ltx.
DATA: lv_userdate TYPE char10.
    
CALL FUNCTION 'HR_IN_GET_DATE_COMPONENTS'
  EXPORTING
    idate                         = sy-datum    " Eingabedatum
  IMPORTING
    day                           = lv_day
    month                         = lv_month
    year                          = lv_year
    stext                         = lv_stext
    ltext                         = lv_ltext
    userdate                      = lv_userdate " Datumsstring abhängig vom Userprofil
  EXCEPTIONS
    input_date_is_initial         = 1
    text_for_month_not_maintained = 2
    OTHERS                        = 3.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

[ABAP] Monatsnamen ermitteln (sprachabhängig) 

DATA: it_month_names TYPE STANDARD TABLE OF t247.
DATA: rc TYPE sy-subrc.

CALL FUNCTION 'MONTH_NAMES_GET'
  EXPORTING
    language              = sy-langu
  IMPORTING
    return_code           = rc
  TABLES
    month_names           = it_month_names
  EXCEPTIONS
    month_names_not_found = 1
    OTHERS                = 2.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ELSE.
  IF rc = 0.
    LOOP AT it_month_names INTO DATA(wa).
      WRITE: / wa-spras, wa-mnr, wa-ktx, wa-ltx.
    ENDLOOP.
  ENDIF.
ENDIF.

[ABAP] Popup mit einspaltige Auswahl (Tabelle) anzeigen 

TYPES: BEGIN OF t_line,
         vorname TYPE char255,
         name    TYPE char255,
         age     TYPE i,
       END OF t_line.

DATA: it_selection TYPE STANDARD TABLE OF t_line.
DATA: lv_choise TYPE i.

it_selection = VALUE #( ( vorname = 'Horst' name = 'Lehmann' age = '70' )
                        ( vorname = 'Udo' name = 'Beyer' age = '50' )
                        ( vorname = 'Heinz' name = 'Schmidt' age = '50' ) ).

CALL FUNCTION 'POPUP_WITH_TABLE_DISPLAY'
  EXPORTING
    endpos_col   = 20
    endpos_row   = 20
    startpos_col = 3
    startpos_row = 3
    titletext    = 'Auswahl'
  IMPORTING
    choise       = lv_choise
  TABLES
    valuetab     = it_selection
  EXCEPTIONS
    break_off    = 1
    OTHERS       = 2.

IF sy-subrc <> 0.
ELSE.
  IF lv_choise EQ 0.
    WRITE 'Nichts ausgewählt.'.
  ELSE.
    WRITE: / 'Zeile: ', lv_choise.
    WRITE: / 'Wert:', it_selection[ lv_choise ]-name.
  ENDIF.
ENDIF.

[ABAP] BDC (Batch Data Communication / Batch-Input)

Transaktionsrecorder zur Aufzeichnung der Bedienschritte: SHDB

Variante 1 (Sofortige Ausführung über CALL TRANSACTION)

DATA: it_batchdata TYPE STANDARD TABLE OF bdcdata.
DATA: it_params TYPE STANDARD TABLE OF rfc_spagpa.
DATA: it_msg TYPE STANDARD TABLE OF bdcmsgcoll.
DATA: lv_mode TYPE sy-ftype.
DATA: lv_update TYPE sy-ftype.

* A = Ausführen im Vordergrund (Hell abspielen, mit Bestätigungen)
* E = Ausführen im Hintergrund, aber Stoppen bei Fehler (dunkel abspielen, bei Fehler hell)
* N = Ausführen im Hintergrund, sammeln Fehler in Fehlertabelle (dunkel abspielen), bei Break-Point Abbruch
* P = Ausführen im Hintergrund, sammeln Fehler in Fehlertabelle (dunkel abspielen), bei Break-Point Sprung in Debugger
lv_mode = 'A'.
* A = Asynchrone Verbuchung. Verbuchungen des aufgerufenen Programms werden so durchgeführt, als sei bei der Anweisung COMMIT WORK der Zusatz AND WAIT nicht angegeben.
* S = Synchrone Verbuchung. Verbuchungen des aufgerufenen Programms werden so durchgeführt, als sei bei der Anweisung COMMIT WORK der Zusatz AND WAIT angegeben.
* L = Lokale Verbuchung. Verbuchungen des aufgerufenen Programms werden durchgeführt, als sei in ihm die Anweisung SET UPDATE TASK LOCAL ausgeführt worden.
lv_update = 'A'.

it_batchdata = VALUE #( ( program = 'SAPMV45A' dynpro = '0102' dynbegin = 'X' fnam = '' fval = '' )        " Einstiegsbildschirm aufrufen
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_CURSOR' fval = 'VBAK-VBELN' ) " Einstiegsbildschirm aufrufen
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'VBAK-VBELN' fval = '122' )    " OK-Code übergeben
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_OKCODE' fval = '=SUCH' )
                        ( program = 'SAPMV45A' dynpro = '4001' dynbegin = 'X' fnam = '' fval = '' )
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_OKCODE' fval = '/EBABA' ) ).       " Bildschirm füllen

* ohne neuen Task und ohne Berechtigungsprüfungen starten
*CALL TRANSACTION 'VA03'
*  USING it_batchdata
*  MODE lv_mode
*  UPDATE lv_update
*  MESSAGES INTO it_msg.

* in neuem Task (Fenster) mit Berechtigungsprüfung starten
CALL FUNCTION 'ABAP4_CALL_TRANSACTION' STARTING NEW TASK 'PROGRAM_1'
  EXPORTING
    tcode                   = 'VA03'
    skip_screen             = abap_false
    mode_val                = lv_mode
    update_val              = lv_update
  TABLES
    using_tab               = it_batchdata
    spagpa_tab              = it_params
    mess_tab                = it_msg
  EXCEPTIONS
    call_transaction_denied = 1
    tcode_invalid           = 2
    OTHERS                  = 3.

CASE sy-subrc.
  WHEN 0.
    WRITE: / 'Ok.'.
  WHEN 1.
    WRITE: / 'call_transaction_denied'.
  WHEN 2.
    WRITE: / 'tcode_invalid.'.
  WHEN OTHERS.
    WRITE: / 'Other error.'.
ENDCASE.

LOOP AT it_msg ASSIGNING FIELD-SYMBOL(<fl_msg>).
  WRITE: / <fl_msg>-dyname.
ENDLOOP.

Variante 2 (neue Mappe, die in der Transaktion SM35 (Batch-Input: Mappenübersicht) eingesehen werden kann, erstellen)

DATA: t_bdcdata LIKE TABLE OF bdcdata.
DATA: fs_bdcdata LIKE LINE OF t_bdcdata.

* Mappe öffnen
CALL FUNCTION 'BDC_OPEN_GROUP'
  EXPORTING
    client              = sy-mandt
    group               = 'MAPPENNAME' " hier Namen der Mappe eintragen
    keep                = 'X'
    user                = sy-uname
  EXCEPTIONS
    client_invalid      = 1
    destination_invalid = 2
    group_invalid       = 3
    group_is_locked     = 4
    holddate_invalid    = 5
    internal_error      = 6
    queue_error         = 7
    running             = 8
    system_lock_error   = 9
    user_invalid        = 10
    OTHERS              = 11.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

* Batchdaten zur Mappe hinzufügen (Beispiel)
* z.B. Programmaufruf
CLEAR fs_bdcdata.
fs_bdcdata-program = 'SAPMM06B'.  " Programmname
fs_bdcdata-dynpro = '0100'.       " Dynpro
fs_bdcdata-dynbegin = 'X'.        " Screen start
APPEND fs_bdcdata TO t_bdcdata.

* z.B. Feldwerte eintragen
CLEAR fs_bdcdata.
fs_bdcdata-fnam = 'EBAN-BSART'.   " Feldname
fs_bdcdata-fval = fs_field-bsart. " Feldwert
CONDENSE fs_bdcdata-fval.
APPEND fs_bdcdata TO t_bdcdata.

* z.B. Aktion auslösen
CLEAR fs_bdcdata.
fs_bdcdata-fnam = 'BDC_OKCODE'.   " OK-Code
fs_bdcdata-fval = '/00'.          " Enter (z.B. '=BU' -> Save, '=SAV' -> Save, '=BACK' -> Zurück)
CONDENSE fs_bdcdata-fval.
APPEND fs_bdcdata TO t_bdcdata.

CALL FUNCTION 'BDC_INSERT'
  EXPORTING
    tcode            = 'ME51'
  TABLES
    dynprotab        = t_bdcdata
  EXCEPTIONS
    internal_error   = 1
    not_open         = 2
    queue_error      = 3
    tcode_invalid    = 4
    printing_invalid = 5
    posting_invalid  = 6
    OTHERS           = 7.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

* Mappe schließen
CALL FUNCTION 'BDC_CLOSE_GROUP'
  EXCEPTIONS
    not_open    = 1
    queue_error = 2
    OTHERS      = 3.

IF sy-subrc NE 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

Weiterführende Infos: Link

[ABAP] ALV – Auswahlpopup für Selektion einer Anzeigevariante anzeigen 

DATA: ls_variant LIKE disvariant.
DATA: lv_exit TYPE c.

PARAMETERS p_vari LIKE disvariant-variant.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_vari.

  CLEAR ls_variant.

  ls_variant-report = sy-repid.
  ls_variant-username = sy-uname.

  CALL FUNCTION 'REUSE_ALV_VARIANT_F4'
    EXPORTING
      is_variant    = ls_variant
      i_save        = 'A'
    IMPORTING
      e_exit        = lv_exit
      es_variant    = ls_variant
    EXCEPTIONS
      not_found     = 1
      program_error = 2
      OTHERS        = 3.

  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ELSE.
    IF lv_exit EQ space.
      p_vari = ls_variant-variant.
    ENDIF.
  ENDIF.