[ABAP] Listausgabe eines Reports holen, anzeigen bzw. weiterverarbeiten

* https://blogs.sap.com/2016/12/29/exporting-list-to-memory-and-its-dangers/

* beliebigen Report ausführen, der eine Listausgabe hat
SUBMIT showcolo EXPORTING LIST TO MEMORY AND RETURN.

DATA: it_list TYPE STANDARD TABLE OF abaplist WITH DEFAULT KEY.

* Einlesen aufbereiteter Liste aus Memory
CALL FUNCTION 'LIST_FROM_MEMORY'
  TABLES
    listobject = it_list
  EXCEPTIONS
    not_found  = 1
    OTHERS     = 2.

IF sy-subrc = 0.
* Listausgabe des aufgerufenen Reports hier anzeigen
* Anzeigen eines (gesicherten) Listobjekts
  CALL FUNCTION 'WRITE_LIST'
    TABLES
      listobject = it_list
    EXCEPTIONS
      empty_list = 1
      OTHERS     = 2.

  IF sy-subrc = 0.
* Speicher (Liste) freigeben
* Löschen der letzten gespeicherten Liste aus dem Memory
    CALL FUNCTION 'LIST_FREE_MEMORY'.
  ENDIF.

  DATA: it_list_string_ascii TYPE list_string_table.

* Listausgabe -> String
* Konvertieren eines (gesicherten) Listobjekts nach ASCI
  CALL FUNCTION 'LIST_TO_ASCI'
    IMPORTING
      list_string_ascii  = it_list_string_ascii
    TABLES
      listobject         = it_list
    EXCEPTIONS
      empty_list         = 1
      list_index_invalid = 2
      OTHERS             = 3.

  IF sy-subrc = 0.
    cl_demo_output=>write_data( it_list_string_ascii ).
  ENDIF.

  DATA: it_html TYPE STANDARD TABLE OF w3html.

* Listausgabe -> HTML
* Converts a given listobject to html
  CALL FUNCTION 'WWW_HTML_FROM_LISTOBJECT'
    TABLES
      html       = it_html
      listobject = it_list.

  cl_demo_output=>write_data( it_html ).

  cl_demo_output=>display( ).
ENDIF.