Start SAP ABAP Archiv nach Kategorie "GUI"

Kategorie: GUI

[ABAP] SALV: Events abfangen beim Klick auf die ALV Funktions-Buttons am Beispiel Filter-Setzen 

CLASS lcl_salv DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS: on_before_function FOR EVENT before_salv_function OF cl_salv_events_table
      IMPORTING e_salv_function
                sender.

    CLASS-METHODS: on_after_function FOR EVENT after_salv_function OF cl_salv_events_table
      IMPORTING e_salv_function
                sender.
ENDCLASS.

CLASS lcl_salv IMPLEMENTATION.
* Event vor ALV-Button Klick
  METHOD on_before_function.
* Werte für e_salv_function sind in cl_salv_gui_ui_function_tools=>cs_list_ui_function deklariert
    CASE e_salv_function.
* '&ETA'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-detail.
        MESSAGE |Details { e_salv_function }| TYPE 'S'.
* '&ILT'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-filter.
        MESSAGE |Filter { e_salv_function }| TYPE 'S'.
* '%PC'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-system_localfile.
        MESSAGE |Export { e_salv_function }| TYPE 'S'.
      WHEN OTHERS.
        MESSAGE |Before Other { e_salv_function }| TYPE 'S'.
    ENDCASE.
  ENDMETHOD.

* Event nach ALV-Button Klick
  METHOD on_after_function.
* Werte für e_salv_function sind in cl_salv_gui_ui_function_tools=>cs_list_ui_function deklariert
    CASE e_salv_function.
* '&ETA'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-detail.
        MESSAGE |Details { e_salv_function }| TYPE 'S'.
* '&ILT'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-filter.
        MESSAGE |Filter { e_salv_function }| TYPE 'S'.
* '%PC'
      WHEN cl_salv_gui_ui_function_tools=>cs_list_ui_function-system_localfile.
        MESSAGE |Export { e_salv_function }| TYPE 'S'.
      WHEN OTHERS.
        MESSAGE |After Other { e_salv_function }| TYPE 'S'.
    ENDCASE.
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.

  SELECT FROM mara
    FIELDS *
    INTO TABLE @DATA(it_mara)
    UP TO 10 ROWS.

    try.
* SALV-Table
  DATA: o_salv TYPE REF TO cl_salv_table.

  cl_salv_table=>factory( IMPORTING r_salv_table = o_salv
                          CHANGING  t_table      = it_mara ).

* Grundeinstellungen
  o_salv->get_functions( )->set_all( abap_true ).
  o_salv->get_columns( )->set_optimize( abap_true ).
  o_salv->get_display_settings( )->set_list_header( 'Überschrift' ).
  o_salv->get_display_settings( )->set_striped_pattern( abap_true ).
  o_salv->get_selections( )->set_selection_mode( if_salv_c_selection_mode=>row_column ).

* Spaltenüberschriften: technischer Name und Beschreibungstexte, Short Text und Medium Text leer lassen für Autosize
  LOOP AT o_salv->get_columns( )->get( ) ASSIGNING FIELD-SYMBOL(<c>).
    DATA(o_col) = <c>-r_column.
    o_col->set_short_text( || ).
    o_col->set_medium_text( || ).
    o_col->set_long_text( |{ o_col->get_columnname( ) } [{ o_col->get_long_text( ) }]| ).
  ENDLOOP.

* Event-Handler für Klick auf die ALV-Funktionsbuttons (Sort, Filter, Export...)
  SET HANDLER lcl_salv=>on_before_function FOR o_salv->get_event( ).
  SET HANDLER lcl_salv=>on_after_function FOR o_salv->get_event( ).

  o_salv->display( ).
CATCH cx_root INTO DATA(e_txt).
  WRITE: / e_txt->get_text( ).
ENDTRY.

[ABAP] Informationen zu einer Einkäufergruppe als Popup anzeigen 

PARAMETERS: p_ekgrp TYPE t024-ekgrp.

START-OF-SELECTION.

  SELECT FROM t024
    FIELDS *
    WHERE ekgrp EQ @p_ekgrp
    INTO TABLE @DATA(it_t024).

  IF sy-subrc = 0.

    TRY.
        DATA: o_pop_ekgrp TYPE REF TO cl_salv_table.

        cl_salv_table=>factory( IMPORTING r_salv_table = o_pop_ekgrp
                                CHANGING  t_table      = it_t024 ).

        o_pop_ekgrp->get_functions( )->set_all( abap_true ).
        o_pop_ekgrp->get_columns( )->set_optimize( abap_true ).
        o_pop_ekgrp->get_display_settings( )->set_list_header( 'Einkäufergruppe' ).
        o_pop_ekgrp->get_display_settings( )->set_striped_pattern( abap_true ).
        o_pop_ekgrp->get_selections( )->set_selection_mode( if_salv_c_selection_mode=>row_column ).

        o_pop_ekgrp->set_screen_popup( start_column = 1
                                       end_column   = 140
                                       start_line   = 1
                                       end_line     = 20 ).
        o_pop_ekgrp->display( ).
      CATCH cx_root INTO DATA(e_txt).
        WRITE: / e_txt->get_text( ).
    ENDTRY.

  ENDIF.

[ABAP] SALV: Selektierte Zeilen (selected rows) eines SALV-Gitters auswerten 

* Beispiel für die Auswertung von selektierten Zeilen eines SALV-Grids,
* nachdem ein Button in der Toolbar geklickt wurde
CLASS lcl_salv DEFINITION FINAL.

  PUBLIC SECTION.

* Variablen
    CLASS-DATA: it_data TYPE ty_it_mytable.
    CLASS-DATA: o_salv TYPE REF TO cl_salv_table.
	
* Eventhandler-Methode für Button-Klicks in der Toolbar des SALV-Grids
    CLASS-METHODS: on_toolbar_click FOR EVENT added_function OF cl_salv_events_table
      IMPORTING
        e_salv_function
        sender.
ENDCLASS.

CLASS lcl_salv IMPLEMENTATION.

  METHOD on_toolbar_click.
	TRY.
		IF o_salv IS BOUND.

		  CASE e_salv_function.

			WHEN 'BTN_CHECK'.

* selektierte Zeilen des SALV-Grids holen
			  DATA(it_sel_rows) = o_salv->get_selections( )->get_selected_rows( ).
			  IF lines( it_sel_rows ) > 0.
* Daten aus der internen Tabelle holen
				DATA(it_items) = VALUE ty_it_mytable( FOR <s> IN it_sel_rows ( it_data[ <s> ] ) ).

				...


			  ENDIF.

		  ENDCASE.

		ENDIF.

	  CATCH cx_root INTO DATA(e_txt).
		MESSAGE e_txt->get_text( ) TYPE 'I'.
	ENDTRY.

  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.

    TRY.
        cl_salv_table=>factory( EXPORTING r_container  = cl_gui_container=>default_screen
                                IMPORTING r_salv_table = lcl_salv=>o_salv
                                CHANGING  t_table      = lcl_salv=>it_data ).
        ...

* eigenen Button in die Toolbar hinzufügen		
        lcl_salv=>o_salv->get_functions( )->add_function( name = 'BTN_CHECK'
                                                          icon = |{ icon_icon_list }|
                                                          text = 'Check'
                                                          tooltip = 'Check'
                                                          position = if_salv_c_function_position=>right_of_salv_functions ).

* Klick-Handler für Toolbar-Buttons													  
        SET HANDLER lcl_salv=>on_toolbar_click FOR lcl_salv=>o_salv->get_event( ).

        ...
		
        lcl_salv=>o_salv->display( ).

* Listausgabe erzwingen für Erzeugung von cl_gui_container=>default_screen
        WRITE: space.

      CATCH cx_root INTO DATA(e_txt).
        WRITE: / e_txt->get_text( ).
    ENDTRY.

[ABAP] SALV: Button-Separator in der SALV-Toolbar einfügen 

START-OF-SELECTION.
    TRY.
        DATA: o_salv TYPE REF TO cl_salv_table.

        cl_salv_table=>factory( EXPORTING r_container  = cl_gui_container=>default_screen
                                IMPORTING r_salv_table = o_salv
                                CHANGING  t_table      = it_... ).

        ...
								
* Standardmäßig ist beim SALV-Grid nicht vorgesehen, dass ein sog. Button-Separator zur optischen Trennung
* der Bedienbuttons in der SALV-Toolbar eingefügt werden kann. Im Beispiel wird daher ein Standard-Button eingefügt, der
* disabled dargestellt wird (ausgegraut):
        DATA(o_separator) = o_salv->get_functions( )->add_function( name = 'BTN_SEPARATOR|'
                                                                    text = '|'
                                                                    tooltip = ''
                                                                    position = if_salv_c_function_position=>right_of_salv_functions ).
        o_separator->set_enable( abap_false ).

        ...

        o_salv->display( ).

* Listausgabe erzwingen für Erzeugung von cl_gui_container=>default_screen
        WRITE: space.

    CATCH cx_root INTO DATA(e_txt).
        WRITE: / e_txt->get_text( ).
    ENDTRY.

[ABAP] SALV: Druckausgabe eines SALV-Gitters in SAP-Spool (SP01)

Druckausgabe per ABAP-Code anschieben

SELECT * INTO TABLE @DATA(it_ispfli) FROM spfli UP TO 50 ROWS.

IF sy-subrc = 0.
  TRY.
      DATA: o_salv TYPE REF TO cl_salv_table.

      cl_salv_table=>factory( IMPORTING r_salv_table = o_salv
                              CHANGING  t_table      = it_ispfli ).

      DATA: lv_print_params TYPE pri_params.

* Druckparameter holen
      CALL FUNCTION 'GET_PRINT_PARAMETERS'
        EXPORTING
          no_dialog              = abap_true
        IMPORTING
          out_parameters         = lv_print_params
        EXCEPTIONS
          archive_info_not_found = 1
          invalid_print_params   = 2
          invalid_archive_params = 3
          OTHERS                 = 4.

      IF sy-subrc = 0.
* nur Drucken in Spool, keine Anzeige des ALV-Grids

* Name eines Geräts
        lv_print_params-pdest = 'LOCL'.
* Beschreibungstext
        lv_print_params-prtxt = |{ sy-datum } { sy-uzeit }|.

* Druckparameter setzen
        DATA(o_print) = o_salv->get_print( ).
        DATA(lv_print_ctrl) = o_print->get_print_control( ).
        lv_print_ctrl-pri_params = lv_print_params.

        o_print->set_print_control( lv_print_ctrl ).
        o_print->set_print_only( abap_true ).

* SALV-Grid anzeigen
        o_salv->display( ).
      ENDIF.

    CATCH cx_root INTO DATA(e_txt).
      WRITE: / e_txt->get_text( ).
  ENDTRY.
ENDIF.

Druckausgabe im Batchmodus

SELECT * INTO TABLE @DATA(it_ispfli) FROM spfli UP TO 50 ROWS.

IF sy-subrc = 0.
* Wenn Batchmodus aktiv, dann nur SALV-Objekt erzeugen und per display( ) ausgeben.
* Das SALV-Grid erzeugt automatisch eine Listausgabe der Tabelle in die Spool.
  IF sy-batch = abap_true.
    TRY.
        DATA: o_salv TYPE REF TO cl_salv_table.

        cl_salv_table=>factory( IMPORTING r_salv_table = o_salv
                                CHANGING  t_table      = it_ispfli ).

* Tabelle im Spool ausgeben
        o_salv->display( ).

      CATCH cx_root INTO DATA(e_txt).
        WRITE: / e_txt->get_text( ).
    ENDTRY.
  ENDIF.
ENDIF.

[ABAP] SALV-Grid: Eventhandler für Doppelklick auf eine Zelle (double_click) 

CLASS lcl_salv DEFINITION FINAL.

  PUBLIC SECTION.

    TYPES: BEGIN OF ty_mara_makt,
             matnr TYPE mara-matnr,
             laeda TYPE mara-laeda,
             mtart TYPE mara-mtart,
             meins TYPE mara-meins,
             maktx TYPE makt-maktx,
           END OF ty_mara_makt.

    CLASS-DATA: o_salv TYPE REF TO cl_salv_table.
    CLASS-DATA: it_mara TYPE STANDARD TABLE OF ty_mara_makt WITH DEFAULT KEY.

    CLASS-METHODS on_double_click FOR EVENT double_click OF cl_salv_events_table
      IMPORTING
        row
        column
        sender.
ENDCLASS.

CLASS lcl_salv IMPLEMENTATION.

  METHOD on_double_click.
    IF o_salv IS BOUND.
* Wenn Spalte 'MATNR'
      IF column EQ 'MATNR'.
* Wert in der geklickten Zelle holen
        DATA(lv_matnr18) = CONV matnr18( o_salv->get_selections( )->get_current_cell( )-value ).

* aufgrund Änderungen im SALV-Klassenmodell ist bei bestimmten SP
* der Aufruf von get_current_cell( )-value leer,
* also, hier nochmal auf die "alte" Art die geklickten Zelldaten holen
        IF lv_matnr18 IS INITIAL.
          lv_matnr18 = it_mara[ row ]-matnr.
        ENDIF.

        IF NOT lv_matnr18 IS INITIAL.
* Parameter zum Aufruf MM03:
* https://www.samplecodeabap.com/call-transaction-mm03-with-specific-tab/

* MATNR setzen
          SET PARAMETER ID 'MAT' FIELD lv_matnr18.
* K - Grunddaten anzeigen
          SET PARAMETER ID 'MXX' FIELD 'K'.
* Transaktion MM03 aufrufen (Material anzeigen)
          CALL TRANSACTION 'MM03' AND SKIP FIRST SCREEN.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.

  SELECT FROM mara AS m
    INNER JOIN makt AS t ON m~matnr = t~matnr
    FIELDS m~matnr,
           m~laeda,
           m~mtart,
           m~meins,
           t~maktx
    WHERE t~spras EQ @sy-langu
    INTO TABLE @lcl_salv=>it_mara
    UP TO 50 ROWS.

  IF sy-subrc = 0.
    TRY.
        cl_salv_table=>factory( IMPORTING r_salv_table = lcl_salv=>o_salv
                                CHANGING  t_table      = lcl_salv=>it_mara ).

* Grundeinstellungen
        lcl_salv=>o_salv->get_functions( )->set_all( abap_true ).
        lcl_salv=>o_salv->get_columns( )->set_optimize( abap_true ).
        lcl_salv=>o_salv->get_display_settings( )->set_list_header( 'Material' ).
        lcl_salv=>o_salv->get_display_settings( )->set_striped_pattern( abap_true ).
        lcl_salv=>o_salv->get_selections( )->set_selection_mode( if_salv_c_selection_mode=>row_column ).

* Spaltenüberschriften: technischer Name und Beschreibungstexte, Short Text und Medium Text leer lassen für Autosize
        LOOP AT lcl_salv=>o_salv->get_columns( )->get( ) ASSIGNING FIELD-SYMBOL(<c>).
          DATA(o_col) = <c>-r_column.
          o_col->set_short_text( || ).
          o_col->set_medium_text( || ).
          o_col->set_long_text( |{ o_col->get_long_text( ) }| ).
        ENDLOOP.

* Event-Hanlder für Link-Klick
        SET HANDLER lcl_salv=>on_double_click FOR lcl_salv=>o_salv->get_event( ).

        lcl_salv=>o_salv->display( ).

      CATCH cx_root INTO DATA(e_txt).
        WRITE: / e_txt->get_text( ).
    ENDTRY.
  ENDIF.

Links

[ABAP] Feldkatalog aus Tabellendefinition erstellen 

* Report: BCALV_GRID_DEMO_FCAT_UTIL
DATA: it_internal_table TYPE STANDARD TABLE OF vbeln WITH DEFAULT KEY.

DATA(o_fcat_util) = cl_salv_gui_fieldcatalog_util=>get_instance( it_data = it_internal_table ).
DATA(it_fieldcat) = o_fcat_util->get_field_catalog( ).

* Hier Objekte für die Ausgabe hinzufügen
cl_demo_output=>write_data( it_fieldcat ).

* HTML-Code vom Demo-Output holen
DATA(lv_html) = cl_demo_output=>get( ).

* Daten im Inline-Browser im SAP-Fenster anzeigen
cl_abap_browser=>show_html( EXPORTING
							title        = 'Feldkatalog'
							html_string  = lv_html
							container    = cl_gui_container=>default_screen ).

* cl_gui_container=>default_screen erzwingen
WRITE: space.

Links

[ABAP] SALV-Grid: Eventhandler für Klick auf eine Zelle (link_click, hotspot) 

CLASS lcl_salv DEFINITION FINAL.

  PUBLIC SECTION.

    TYPES: BEGIN OF ty_mara_makt,
             matnr TYPE mara-matnr,
             laeda TYPE mara-laeda,
             mtart TYPE mara-mtart,
             meins TYPE mara-meins,
             maktx TYPE makt-maktx,
           END OF ty_mara_makt.

    CLASS-DATA: o_salv TYPE REF TO cl_salv_table.
    CLASS-DATA: it_mara TYPE STANDARD TABLE OF ty_mara_makt WITH DEFAULT KEY.

    CLASS-METHODS on_link_click FOR EVENT link_click OF cl_salv_events_table
      IMPORTING
        row
        column
        sender.
ENDCLASS.

CLASS lcl_salv IMPLEMENTATION.

  METHOD on_link_click.
    IF o_salv IS BOUND.
* Wenn Spalte 'MATNR'
      IF column EQ 'MATNR'.
* Wert in der geklickten Zelle holen
        DATA(lv_matnr18) = CONV matnr18( o_salv->get_selections( )->get_current_cell( )-value ).

* aufgrund Änderungen im SALV-Klassenmodell ist bei bestimmten SP
* der Aufruf von get_current_cell( )-value leer,
* also, hier nochmal auf die "alte" Art die geklickten Zelldaten holen
        IF lv_matnr18 IS INITIAL.
          lv_matnr18 = it_mara[ row ]-matnr.
        ENDIF.

        IF NOT lv_matnr18 IS INITIAL.
* Parameter zum Aufruf MM03:
* https://www.samplecodeabap.com/call-transaction-mm03-with-specific-tab/

* MATNR setzen
          SET PARAMETER ID 'MAT' FIELD lv_matnr18.
* K - Grunddaten anzeigen
          SET PARAMETER ID 'MXX' FIELD 'K'.
* Transaktion MM03 aufrufen (Material anzeigen)
          CALL TRANSACTION 'MM03' AND SKIP FIRST SCREEN.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.

  SELECT FROM mara AS m
    INNER JOIN makt AS t ON m~matnr = t~matnr
    FIELDS m~matnr,
           m~laeda,
           m~mtart,
           m~meins,
           t~maktx
    WHERE t~spras EQ @sy-langu
    INTO TABLE @lcl_salv=>it_mara
    UP TO 50 ROWS.

  IF sy-subrc = 0.
    TRY.
        cl_salv_table=>factory( IMPORTING r_salv_table = lcl_salv=>o_salv
                                CHANGING  t_table      = lcl_salv=>it_mara ).

* Grundeinstellungen
        lcl_salv=>o_salv->get_functions( )->set_all( abap_true ).
        lcl_salv=>o_salv->get_columns( )->set_optimize( abap_true ).
        lcl_salv=>o_salv->get_display_settings( )->set_list_header( 'Material' ).
        lcl_salv=>o_salv->get_display_settings( )->set_striped_pattern( abap_true ).
        lcl_salv=>o_salv->get_selections( )->set_selection_mode( if_salv_c_selection_mode=>row_column ).

* Spaltenüberschriften: technischer Name und Beschreibungstexte, Short Text und Medium Text leer lassen für Autosize
        LOOP AT lcl_salv=>o_salv->get_columns( )->get( ) ASSIGNING FIELD-SYMBOL(<c>).
          DATA(o_col) = <c>-r_column.
          o_col->set_short_text( || ).
          o_col->set_medium_text( || ).
          o_col->set_long_text( |{ o_col->get_long_text( ) }| ).
        ENDLOOP.

* Link-Klick für Spalte MATNR
        CAST cl_salv_column_table( lcl_salv=>o_salv->get_columns( )->get_column( 'MATNR' ) )->set_cell_type( if_salv_c_cell_type=>hotspot ).

* Event-Hanlder für Link-Klick
        SET HANDLER lcl_salv=>on_link_click FOR lcl_salv=>o_salv->get_event( ).

        lcl_salv=>o_salv->display( ).

      CATCH cx_root INTO DATA(e_txt).
        WRITE: / e_txt->get_text( ).
    ENDTRY.
  ENDIF.