Zum Inhalt springen
Die Codezentrale
Programmierung, Tipps, Tricks, Snippets, Links (.Net, Java, JavaScript, C++, PHP, Python, SQL, SAP, ABAP, SAPUI5)
Zum Inhalt springen
  • Home
  • Links
    • Kachelmannwetter
    • MrLeehs Blog
    • Deskmodder
    • winfuture.de
    • Tricktresor
    • Python Online Compiler
    • [Raspberry Pi] Wichtige Terminal-Kommandos für Raspian
    • CodeSandbox JS Vanilla
  • Datenschutzerklärung
  • Impressum
Startseite SAP ABAP GUI Grid ALV [ABAP] ALV-Grid: Einfaches Beispiel zur Anzeige von Daten in einem ALV-Grid (cl_gui_alv_grid)

[ABAP] ALV-Grid: Einfaches Beispiel zur Anzeige von Daten in einem ALV-Grid (cl_gui_alv_grid)

admin 11. Juni 2019 11. Juni 2019ALV
START-OF-SELECTION.
* Daten holen
  SELECT *
    INTO TABLE @DATA(it_spfli)
    FROM spfli
    WHERE carrid = 'LH'.

* ALV-Gitter-Objekt erzeugen
  DATA(o_alv) = NEW cl_gui_alv_grid( i_parent      = cl_gui_container=>default_screen " in default container einbetten
                                     i_appl_events = abap_true ).                     " Ereignisse als Applikationsevents registrieren

* Feldkatalog automatisch durch SALV-Objekte erstellen lassen
  DATA: o_salv TYPE REF TO cl_salv_table.

  cl_salv_table=>factory( IMPORTING
                            r_salv_table = o_salv
                          CHANGING
                            t_table      = it_spfli ).

  DATA(it_fcat) = cl_salv_controller_metadata=>get_lvc_fieldcatalog( r_columns      = o_salv->get_columns( )
                                                                     r_aggregations = o_salv->get_aggregations( ) ).

* Layout des ALV setzen
  DATA(lv_layout) = VALUE lvc_s_layo( zebra      = abap_true             " ALV-Control: Alternierende Zeilenfarbe (Zebramuster)
                                      cwidth_opt = 'A'                   " ALV-Control: Spaltenbreite optimieren
                                      grid_title = 'Flugverbindungen' ). " ALV-Control: Text der Titelzeile

* ALV anzeigen
  o_alv->set_table_for_first_display( EXPORTING
                                        i_bypassing_buffer = abap_false  " Puffer ausschalten
                                        i_save             = 'A'         " Anzeigevariante sichern
                                        is_layout          = lv_layout   " Layout
                                      CHANGING
                                        it_fieldcatalog    = it_fcat     " Feldkatalog
                                        it_outtab          = it_spfli ). " Ausgabetabelle

* Focus auf ALV setzen
  cl_gui_alv_grid=>set_focus( control = o_alv ).

* leere SAP-Toolbar ausblenden
  cl_abap_list_layout=>suppress_toolbar( ).

* erzwingen von cl_gui_container=>default_screen
  WRITE: space.
  ABAP, cl_abap_list_layout, cl_gui_alv_grid, cl_gui_container, cl_salv_controller_metadata, cl_salv_table, default_screen, get_aggregations, get_columns, get_lvc_fieldcatalog, lvc_s_layo, set_focus, set_table_for_first_display, suppress_toolbar. Lesezeichen.
[ABAP] ABAP Release 7.50: Host Expressions, SQL Expressions, Path Expressions
[ABAP] Verarbeitungsstatus von Nachrichten aus der Tabelle NAST lesen
  • Kategorien

    aufklappen | zuklappen
  • Neueste Beiträge

    • [SAP Fiori] OK-Code Feld in Fiori-Apps anzeigen
    • [ABAP] Auswahl eines Transportauftrags (mit Anlegen)
    • Spanische Vokabeln
    • Deutsch
    • Englisch
    • Spanisch
    • [ABAP] Verschieben von Nodes per Drag & Drop innerhalb einer Baumansicht (CL_COLUMN_TREE_MODEL)
    • [SAP] Screen Personas
    • Weltall / Raumfahrt
    • [CDS-Views] Virtuelle Elemente: Aufruf von ABAP-Coding aus CDS-Views heraus
  • Archiv

  • Meta

    • Anmelden
    • Feed der Einträge
    • Kommentare-Feed
    • WordPress.org
  • Tags

    ABAP (880) Android (18) CLASS (20) cl_abap_list_layout (18) cl_abap_matcher (13) cl_bcs_convert (16) cl_gui_alv_grid (23) cl_gui_container (35) cl_gui_docking_container (23) cl_gui_frontend_services (36) cl_salv_table (52) cntl_simple_event (16) create (28) DataGridView (13) Date (15) default_screen (28) display (14) EWM (16) Fiori (16) get_column (13) get_columns (22) gui_download (14) HTML (14) JavaScript (78) JSON (20) MIME (17) NEW (20) OData (29) OpenSQL (21) Python (23) Raspberry Pi (50) Raspberry Pi 2 (27) Raspberry Pi 4 (23) Raspian (22) RegEx (17) SAP (351) SAPUI5 (27) SELECT (25) String (33) stringtab (15) suppress_toolbar (19) UTF-8 (14) Value (26) XML (25) xstring (20)
(W) 2023 by codezentrale.de
Powered by Tempera & WordPress.