Startseite Beiträge getaggt mit "CALL TRANSACTION"

Schlagwort: CALL TRANSACTION

[ABAP] Materialbelegliste (MB51) anzeigen

Variante 1 (CALL TRANSACTION)

PARAMETERS: p_werk TYPE werks DEFAULT '10'.
PARAMETERS: p_matnr TYPE matnr.
PARAMETERS: p_lgort TYPE lgort_d.
PARAMETERS: p_bwart TYPE bwart.
PARAMETERS: p_charg TYPE charg_d.
PARAMETERS: p_lifnr TYPE lifnr.
PARAMETERS: p_kunnr TYPE kunnr.
PARAMETERS: p_kdauf TYPE kdauf.

START-OF-SELECTION.

* Werk
  SET PARAMETER ID 'WRK' FIELD p_werk.
* Material
  SET PARAMETER ID 'MAT' FIELD p_matnr.
* Lagerort
  SET PARAMETER ID 'LAG' FIELD p_lgort.
* Bewegungsart
  SET PARAMETER ID 'BWA' FIELD p_bwart.
* Charge
  SET PARAMETER ID 'CHA' FIELD p_charg.
* Lieferant
  SET PARAMETER ID 'LIF' FIELD p_lifnr.
* Kunde
  SET PARAMETER ID 'KUN' FIELD p_kunnr.
* Kundenuftrag
  SET PARAMETER ID 'AUN' FIELD p_kdauf.

  CALL TRANSACTION 'MB51' AND SKIP FIRST SCREEN.

Variante 2 (SUBMIT)

* Werk
DATA(lv_werk) = VALUE werks( ).
SELECT-OPTIONS: so_werk FOR lv_werk.
* Warenbegleitscheinnummer
DATA(lv_xabln) = VALUE xabln( ).
SELECT-OPTIONS: so_xabln FOR lv_xabln.
* Referenz-Belegnummer
DATA(lv_xblnr) = VALUE xblnr1( ).
SELECT-OPTIONS: so_xblnr FOR lv_xblnr.

INITIALIZATION.
* Vorbelegung für Werk
  so_werk[] = VALUE #( ( sign = 'I' option = 'EQ' low = '10' high = '' ) ).
  
START-OF-SELECTION.

* MB51 ist eine Reporttransaktion, also kann auch der dahinter
* liegende Report RM07DOCS direkt mit Übergabewerten aufgerufen werden
  SUBMIT rm07docs
    WITH werks IN so_werk
    WITH xabln IN so_xabln
    WITH xblnr IN so_xblnr
    WITH rhier_l = abap_true  " Radiobutton "Hierarchische Liste" aktiv setzen
    WITH rflat_l = abap_false " Radiobutton "Flache Liste" deaktivieren
    AND RETURN.

[ABAP] Auf Daten eines ALV-Grids eines Reports zugreifen

Variante 1 (SUBMIT)

* https://blogs.sap.com/2011/07/07/gain-programmatic-access-to-data-of-sapgui-alv-reports/
* http://www.saptutorial.org/get-data-from-alv-report-sap-standard-and-output-into-internal-table/

* Initialisierung
cl_salv_bs_runtime_info=>set( EXPORTING display  = abap_false   " Report anzeigen?
                                        metadata = abap_true    " Metadaten des ALV-Grids ermitteln?
                                        data     = abap_true ). " Datenimport aus ALV-Grid?

* Selektionsparameter des Reports 'RSVTPROT' (Transaktion SCU3)
DATA: it_sel_par TYPE STANDARD TABLE OF rsparams WITH DEFAULT KEY.

APPEND VALUE #( selname = 'CUSOBJ' " Name Parameter oder Selektionskriterium
                kind    = 'P'      " P - Parameter, S - Selektionskriterium
                sign    = 'I'
                option  = 'EQ'
                low     = 'Z...' ) TO it_sel_par. " NAME des Customizing-Objektes (Z-Tabelle ...)

APPEND VALUE #( selname = 'DBEG' " Name Parameter oder Selektionskriterium
                kind    = 'P'    " P - Parameter, S - Selektionskriterium
                sign    = 'I'
                option  = 'EQ'
                low     = '20170101' ) TO it_sel_par.

APPEND VALUE #( selname = 'DEND' " Name Parameter oder Selektionskriterium
                kind    = 'P'    " P - Parameter, S - Selektionskriterium
                sign    = 'I'
                option  = 'EQ'
                low     = '20171231' ) TO it_sel_par.

APPEND VALUE #( selname = 'TBEG' " Name Parameter oder Selektionskriterium
                kind    = 'P'    " P - Parameter, S - Selektionskriterium
                sign    = 'I'
                option  = 'EQ'
                low     = '000000' ) TO it_sel_par.

APPEND VALUE #( selname = 'TEND' " Name Parameter oder Selektionskriterium
                kind    = 'P'    " P - Parameter, S - Selektionskriterium
                sign    = 'I'
                option  = 'EQ'
                low     = '235959' ) TO it_sel_par.

APPEND VALUE #( selname = 'ALV_GRID' " Name Parameter oder Selektionskriterium
                kind    = 'P'        " P - Parameter, S - Selektionskriterium
                sign    = 'I'
                option  = 'EQ'
                low     = 'X' ) TO it_sel_par.

* Report mit Selektionsparametern aufrufen
SUBMIT rsvtprot WITH SELECTION-TABLE it_sel_par AND RETURN.

TRY.
    DATA: o_alv_data TYPE REF TO data.

* Datenreferenz auf ALV-Daten des Reports
    cl_salv_bs_runtime_info=>get_data_ref( IMPORTING r_data = o_alv_data ).

    IF o_alv_data IS BOUND.
      FIELD-SYMBOLS: <alv> TYPE ANY TABLE.
      ASSIGN o_alv_data->* TO <alv>.

      IF <alv> IS ASSIGNED.

* Metadaten des ALV-Grids
        DATA(lv_metadata) = cl_salv_bs_runtime_info=>get_metadata( ).

* ALV-Grid-Titel
        WRITE: / lv_metadata-s_layout-grid_title.

        ULINE.

* ALV-Spaltentitel (Feldkatalog)
        LOOP AT lv_metadata-t_fcat ASSIGNING FIELD-SYMBOL(<f>).
          WRITE: / <f>-fieldname, <f>-seltext, <f>-tooltip, <f>-reptext, <f>-domname.
        ENDLOOP.

        ULINE.

* Anzahl Spalten
        DATA(lv_col_cnt) = lines( lv_metadata-t_fcat ).

* Datenausgabe
        LOOP AT <alv> ASSIGNING FIELD-SYMBOL(<row>).
          DO lv_col_cnt TIMES.
* Spaltenweise die Zellen der akt. Zeile
            ASSIGN COMPONENT sy-index OF STRUCTURE <row> TO FIELD-SYMBOL(<cell>).
            IF <cell> IS ASSIGNED.
              WRITE: <cell>.
            ENDIF.
          ENDDO.
          SKIP.
        ENDLOOP.

      ENDIF.
    ELSE.
      WRITE: / 'Keine ALV-Daten verfügbar.'.
    ENDIF.

  CATCH cx_root INTO DATA(e_txt).
    WRITE: / e_txt->get_text( ).
ENDTRY.

TRY.
    cl_salv_bs_runtime_info=>clear_all( ).
  CATCH cx_root INTO DATA(e_txt2).
    WRITE: / e_txt2->get_text( ).
ENDTRY.

Variante 2 (CALL TRANSACTION)

* Initialisierung
cl_salv_bs_runtime_info=>set( EXPORTING display  = abap_false   " Report anzeigen?
                                        metadata = abap_true    " Metadaten des ALV-Grids ermitteln?
                                        data     = abap_true ). " Datenimport aus ALV-Grid?

* Selektionparameter "Werk" vorbelegen
SET PARAMETER ID 'WRK' FIELD '10'.
* Transaktion aufrufen
CALL TRANSACTION 'MM60' WITHOUT AUTHORITY-CHECK AND SKIP FIRST SCREEN.

IF sy-subrc = 0.
  TRY.
      DATA: o_alv_data TYPE REF TO data.

* Datenreferenz auf ALV-Daten des Reports
      cl_salv_bs_runtime_info=>get_data_ref( IMPORTING r_data = o_alv_data ).

      IF o_alv_data IS BOUND.
        FIELD-SYMBOLS: <alv> TYPE ANY TABLE.
        ASSIGN o_alv_data->* TO <alv>.

        IF <alv> IS ASSIGNED.

* Metadaten des ALV-Grids
          DATA(lv_metadata) = cl_salv_bs_runtime_info=>get_metadata( ).

* ALV-Grid-Titel
          WRITE: / lv_metadata-s_layout-grid_title.

          ULINE.

* ALV-Spaltentitel (Feldkatalog)
          LOOP AT lv_metadata-t_fcat ASSIGNING FIELD-SYMBOL(<f>).
            WRITE: / <f>-fieldname, <f>-seltext, <f>-tooltip, <f>-reptext, <f>-domname.
          ENDLOOP.

          ULINE.

* Anzahl Spalten
          DATA(lv_col_cnt) = lines( lv_metadata-t_fcat ).

* Datenausgabe
          LOOP AT <alv> ASSIGNING FIELD-SYMBOL(<row>).
            DO lv_col_cnt TIMES.
* Spaltenweise die Zellen der akt. Zeile
              ASSIGN COMPONENT sy-index OF STRUCTURE <row> TO FIELD-SYMBOL(<cell>).
              IF <cell> IS ASSIGNED.
                WRITE: <cell>.
              ENDIF.
            ENDDO.
            SKIP.
          ENDLOOP.

        ENDIF.
      ELSE.
        WRITE: / 'Keine ALV-Daten verfügbar.'.
      ENDIF.

    CATCH cx_root INTO DATA(e_txt).
      WRITE: / e_txt->get_text( ).
  ENDTRY.

  TRY.
      cl_salv_bs_runtime_info=>clear_all( ).
    CATCH cx_root INTO DATA(e_txt2).
      WRITE: / e_txt2->get_text( ).
  ENDTRY.
ENDIF.

[ABAP] Transaktion mit Parametern vorbelegen und aufrufen

Variante 1 (Batch-Input-Daten)

DATA: it_batchdata TYPE STANDARD TABLE OF bdcdata.
DATA: it_msg TYPE STANDARD TABLE OF bdcmsgcoll.
  
* Batch-Input-Daten, mit Transaktion SHDB aufgezeichnet
it_batchdata = VALUE #( ( program = 'SAPLSD_ENTRY' dynpro = '1000' dynbegin = 'X' fnam = '' fval = '' )
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_CURSOR' fval = 'RSRD1-VIMA_VAL' )
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'BDC_OKCODE' fval = '=WB_DISPLAY' )
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'RSRD1-VIMA' fval = 'X' )
                        ( program = '' dynpro = '' dynbegin = '' fnam = 'RSRD1-VIMA_VAL' fval = 'MARA' ) ). 

* SE11 aufrufen, kein AUTHORITY-CHECK
CALL TRANSACTION 'SE11' WITHOUT AUTHORITY-CHECK
  USING it_batchdata
  MODE 'E'
  UPDATE 'A'
  MESSAGES INTO it_msg.

IF sy-subrc NE 0.
  MESSAGE 'Fehler beim Aufruf des SE11' TYPE 'S' DISPLAY LIKE 'E'.
ENDIF.

Variante 2 (SET PARAMETER – SE11)

* Parameter "Datenbakname" mit Wert 'MARA' vorbelegen
SET PARAMETER ID 'DTB' FIELD 'MARA'.
* SE11 ohne Prüfung aufrufen
CALL TRANSACTION 'SE11' WITHOUT AUTHORITY-CHECK.

IF sy-subrc NE 0.
  MESSAGE 'Fehler beim Aufruf des SE11' TYPE 'S' DISPLAY LIKE 'E'.
ENDIF.

Variante 3 (SET PARAMETER – MM03)

PARAMETERS: p_matnr TYPE matnr.

* MATNR setzen
SET PARAMETER ID 'MAT' FIELD p_matnr.
* Grunddaten anzeigen
SET PARAMETER ID 'MXX' FIELD 'K'.
* Transaktion MM03 aufrufen (Material anzeigen)
CALL TRANSACTION 'MM03' AND SKIP FIRST SCREEN.

Variante 4 (SET PARAMETER – ME23N)

* Belegnummer (Bestellung)
PARAMETERS: p_ebeln TYPE ekko-ebeln.

* Belegnummer setzen
SET PARAMETER ID 'BES' FIELD p_ebeln.
* Transaktion ME23N aufrufen (Bestellung anzeigen)
CALL TRANSACTION 'ME23N' AND SKIP FIRST SCREEN.

Links